如何将ArrayList值从脚本声明传输到Groovy脚本测试步骤？

Question

I'm getting array of values from the XML data and I need to store that value in a custom property and then I have to make use of it in the Groovy script.

When I try to write a script like this:

def groovyUtils = new com.eviware.soapui.support.GroovyUtils( context )
def responseHolder = groovyUtils.getXmlHolder( messageExchange.responseContent )

def results = new XmlSlurper().parseText( messageExchange.response.responseContent ) 

if (results != null)
{
    List rowset = results?.ResultSet?.Row?.collect{"${it.OBJ_ID} ${it.REL_OBJ_ID} ${it.CUST_MODEL_CD} ${it.TYPE_CD}"}
    log.info(rowset)

    context.testCase.setPropertyValue("RowData", rowset)
}

I'm getting the following error in the console:

No signature of method: com.eviware.soapui.impl.wsdl.testcase.WsdlTestCase.setPropertyValue() is applicable for argument types: (java.lang.String, java.util.ArrayList) values: [RowData, [18144046 5276601 CI DRVD, 18144050 5276601 CI DRVD, ...]]
Possible solutions: setPropertyValue(java.lang.String, java.lang.String), getPropertyValue(java.lang.String)

How can I transfer these values from Script Assertion to Groovy Script ?

Answer 1

According to exception that is being thrown:

No signature of method: com.eviware.soapui.impl.wsdl.testcase.WsdlTestCase.setPropertyValue() is applicable for argument types: (java.lang.String, java.util.ArrayList) values: [RowData, [18144046 5276601 CI DRVD, 18144050 5276601 CI DRVD, ...]]
Possible solutions: setPropertyValue(java.lang.String, java.lang.String), getPropertyValue(java.lang.String)

setPropertyValue method expects two String parameters.

You can try serializing rowset list to JSON string and passing this string to setPropertyValue . Next, when you need to read it as list all you have to do is to deserialize this JSON string to a List<String> object. Here is how you can do serialization and deserialization using Groovy's classes JsonOutput and JsonSlurper :

import groovy.json.JsonOutput
import groovy.json.JsonSlurper

List<String> rowset = ['18144046 5276601 CI DRVD', '18144050 5276601 CI DRVD']

String json = JsonOutput.toJson(rowset)

List<String> fromJson = new JsonSlurper().parseText(json)

assert rowset == fromJson

Your updated part could look like this:

def groovyUtils = new com.eviware.soapui.support.GroovyUtils( context )
def responseHolder = groovyUtils.getXmlHolder( messageExchange.responseContent )

def results = new XmlSlurper().parseText( messageExchange.response.responseContent )

if (results != null)
{
    List rowset = results?.ResultSet?.Row?.collect{"${it.OBJ_ID} ${it.REL_OBJ_ID} ${it.CUST_MODEL_CD} ${it.TYPE_CD}"}
    log.info(rowset)

    context.testCase.setPropertyValue("RowData", groovy.json.JsonOutput.toJson(rowset))
}

And when you load the data later on you could do:

List<String> rowset = new groovy.json.JsonSlurper().parseText(context.testCase.getPropertyValue("RowData"))

Hope it helps.