sed匹配日期和奇数格式

Question

I am having an issue with sed where I am trying to match based on dates so I can capture all logs from a specific date/time and upload them to an API. I then store the last run date as the new start date.

The problem I have is that the 'start' and 'end' dates are not necessarily present in the file and I want to match as close as I can based on the dates/times. The code i have at the moment it seems to only work if the two dates are present in the source file.

    function logs() {
        timestamplastupload="`cat /tmp/latest-timestamp.txt`"
        timestampnow=`date +"%a %b %_d %H:%M:%S %Y"`
        echo "$timestampnow" > /tmp/latest-timestamp.txt


        while read -r line; do
            curl -X POST -d "$line" https://logserver/api/NewLog --ntlm --user xx:xx       
        done < <(sed -rne '/'"$timestamplastupload"'/,/'"$timestampnow"'/ p' /var/log/fullaccess.log)
    }

Is there a way to specify the sed match to do like or somehow locate the line in the file that is closest so I can ensure I am only uploading new log lines without having do a huge amount of comparison work on the API side with matching every entry in the data store there.

Here is an example of the log file I'm trying to parse:

Thu Mar  1 21:07:14 2018 us=56799   ifconfig_ipv6_pool_netbits = 0
Thu Mar  1 21:07:14 2018 us=56808   n_bcast_buf = 256
Thu Mar  1 21:07:14 2018 us=56817   tcp_queue_limit = 64
Thu Mar  1 21:07:14 2018 us=56826   real_hash_size = 256
Thu Mar  1 21:07:14 2018 us=56835   virtual_hash_size = 256
Wed Feb 28 22:10:48 2018 us=184134   ifconfig_nowarn = DISABLED
Wed Feb 28 22:10:48 2018 us=184143   ifconfig_ipv6_local = '[UNDEF]'
Wed Feb 28 22:10:48 2018 us=184152   ifconfig_ipv6_netbits = 0
Wed Feb 28 22:10:48 2018 us=184161   ifconfig_ipv6_remote = '[UNDEF]'

Also note the padded space before a single date, which might also be throwing a spanner into the works here. I thought I had fixed that by providing date with +%_d

Thanks in advance

Answer 1

Although sed is useful for pattern matching, it may not be suitable for value comparison. AWK will be better in this sense.
A common method for time comparison is to convert the date string into seconds since the epoch. But it will be more practical just to merge date and time into a single number, for instance, converting "Feb 28 22:10:48 2018" into "20180228221048". Here is the example:

function logs() {
    timestamplastupload="`cat /tmp/latest-timestamp.txt`"
    timestampnow=`date +"%a %b %_d %H:%M:%S %Y"`
    echo "$timestampnow" > /tmp/latest-timestamp.txt

    while read -r line; do
        curl -X POST -d "$line" https://logserver/api/NewLog --ntlm --user xx:xx
    done < <(awk -v timestamplastupload="$timestamplastupload" -v timestampnow="$timestampnow" '
    # initialize variables
    BEGIN {
        monstr = "JanFebMarAprMayJunJulAugSepOctNovDec";
        for (i = 1; i <= 12; i++) {
            mon2mm[substr(monstr, i * 3 - 2, 3)] = i;
        }
        split(timestamplastupload, ary, " ");
        start = date2str(ary[2], ary[3], ary[4], ary[5]);
        split(timestampnow, ary, " ");
        end = date2str(ary[2], ary[3], ary[4], ary[5]);
    }
    # merge date and time into a scalar number
    function date2str(mon, day, time, year,
        hms, datestr) {
        split(time, hms, ":");
        datestr = sprintf("%04d%02d%02d%02d%02d%02d",
            year, mon2mm[mon], day, hms[1], hms[2], hms[3]);
        return datestr;
    }
    # main loop
    {
        logtime = date2str($2, $3, $4, $5);
        if (logtime >= start && logtime <= end) {
            print;
        }
    }
    ' /var/log/fullaccess.log)
}

Sorry for the lengthy and non-elegant solution.