使用Groovy进行Jenkins管道模拟

Question

I'm quite new to the Jenkins pipeline stuff and I am building a small shared library in Groovy.
In this context I am trying to come up with some unit tests, and then I have to mock the pipeline object.

Basically I am having a Groovy class containing a method that does some stuff with credentials:

class MyClass implements Serializable {

  def pipeline

  MyClass(def pipeline) {
    this.pipeline = pipeline
  }

  void my method(String version) {
    pipeline.withCredentials([pipeline.usernamePassword(credentialsId: 'MY_ID', usernameVariable: 'MY_USER', passwordVariable: 'MY_PASSWORD')]) {
        pipeline.sh "./release.sh complete --username ${MY_USER} --password ${MY_PASSWORD} --version '${version}'"
    }
  }
}

So when it comes to unit testing this method I have created a PipelineMock Groovy class to (try to) mock the withCredentials and usernamePassword .

The test class is like this (a bit simplified):

class MyClassTest {

  @Test
  void callWithWithVersionShouldCallCommad() {
    def pipelineMock = new PipelineMock()
    def myClass = new MyClass(pipelineMock)
    myClass('1.0.1')
    assertTrue(pipelineMock.commandCalled.startsWith('./release.sh complete'))
  }

}

And the PipelineMock I came up with is:

class PipelineMock {

  String commandCalled

  def sh(String command) {
    commandCalled = command
  }

  def usernamePassword(Map inputs) {
    inputs
  }

  def withCredentials(List args, Closure closure) {
    for (arg in args) {
        closure.setProperty(arg.get('usernameVariable'), 'the_login')
        closure.setProperty(arg.get('passwordVariable'), 'the_password')
    }
    closure()
  }

}

Initially I was just calling the closure() so to execute the code, but I got the error groovy.lang.MissingPropertyException: No such property: MY_USER for class: MyClass when the execution reaches the pipeline.sh line.
So I tried to inject test values into MY_USER and MY_PASSWORD so they can be resolved with the for loop. I got the exact same error but this time when calling the closure.setProperty . I checked at debug time and the arg.get('usernameVariable') resolves correctly to MY_USER .

So well, I'm lost. I'm not really a Groovy expert, so I probably miss something. Any help on understanding what's happening would be appreciated!

Answer 1

This does look like an ideal candidate for using JenkinsPipelineUnit as @mkobit mentioned in a comment, but for the sake of academic interest, the sample in the question would in fact work with minor changes related to delegator. There is also a typo in the original MyClass.my method which I believe should have been MyClass.call . Here is the working PipelineMock

class PipelineMock {

  String commandCalled

  def sh(String command) {
    commandCalled = command
  }

  def usernamePassword(Map inputs) {
    inputs
  }

  def withCredentials(List args, Closure closure) {
    def delegate = [:]
    for (arg in args) {
        delegate[arg.get('usernameVariable')] = 'the_login'
        delegate[arg.get('passwordVariable')] = 'the_password'
    }
    closure.delegate = delegate
    closure()
  }

}

And here is the MyClass without the typo:

class MyClass implements Serializable {

  def pipeline

  MyClass(def pipeline) {
    this.pipeline = pipeline
  }

  void call(String version) {
    pipeline.withCredentials([pipeline.usernamePassword(credentialsId: 'MY_ID', usernameVariable: 'MY_USER', passwordVariable: 'MY_PASSWORD')]) {
        pipeline.sh "echo ./release.sh complete --username ${MY_USER} --password ${MY_PASSWORD} --version '${version}'"
    }
  }
}

The test should work as is.