Excel VBA：如何对具有可变行的Sum公式进行编码以放入工作表

Question

I want to put a Sum formula in a row of a table, in columns C to H, but the code I've come up with somehow doesn't work. The situation is as follows:

1. the number of the 1st row of the table varies (the 1st column is always B)
2. the number of the 1st row in the formula varies, but is always the 3rd row of the table
3. the number of the row that should contain the formula varies, but in the macro I calculate that number relative to the 1st row of the table
4. the number of the last row in the formula varies, but is always 1 less than the number of the row that should contain the formula

To be more specific and hopefully more clear, let's say that:

1. the number of the first row of the table = startnum
2. then the number of the 1st row in the formula = startnum+3
3. the number of the row that should contain the formula = startnum+x
4. then the number of the last row in the formula = startnum+x-1

Trying to find out what my code could be, I recorded a macro. Based on that I have tested the following code:

With Worksheets("A&N")
    .Range("C16:H16").Formula = "=SUM(C7:C15)"
End With

This works fine, but as I've described, the numbers 16, 7 and 15 are actually variable.

I've tried to translate this code to my situation, and made this code:

Set rngOpmaak = Range(rngTabel.Cells(startnum + x, 2), rngTabel.Cells(startnum + x, 7)) 
rngOpmaak.Formula = "=SUM(“C” & startnum + 3 & “:C” & startnum + x -1)"

When I run the macro I get the message that the second line can't be compiled. I've seen solutions on this site that to me look exactly like my code, so I don't understand what's wrong with mine.

I've also tried:

rngOpmaak.FormulaR1C1 = "=SUM(R" & startnum + 3 & "C:R" & startnum + x -1 & "C)"

But with startnum=2 (1st row of the table) the formula becomes =SUM(C$3:C$5) to =SUM(H$3:H$5) (without the quotations) instead of =SUM(C4:C6) to =SUM(H4:H6) .

Can anyone help me with what the line of code should be? All suggestions are much appreciated.

Answer 1

You'll need to adjust this to your situation, as I didn't use the same variables you did (preferring more expressive ones):

Sub test()
    Dim output As Range, dataStart As Integer, dataEnd As Integer, rowsOfData As Integer, nCols As Integer
    ' Row 1: Table headers
    ' Row 2: 1st row of data
    ' Row 3: more data
    ' Row 4: more data
    ' Row 5: last row of data
    ' Row 6: Summary row (location of formula)
    dataStart = 2
    dataEnd = 5
    rowsOfData = 1 + dataEnd - dataStart
    nCols = 4
    Set output = Range(Cells(dataEnd + 1, 1), Cells(dataEnd + 1, nCols))
    output.FormulaR1C1 = "=SUM(R[-" & rowsOfData & "]C:R[-1]C)"
End Sub

The generated formula uses relative references, as it was given offsets ( [] ) from the current cell, rather than absolute R/C values, eg
R2C:R5C -> A$2:A$5 no matter where in column A the formula is entered
R[-4]C:R[-1] -> A2:A5 if the formula is entered in A6 .