使用CAST通过emb-sql更改rpgle上的文本字段CCSID

Question

I have a file defined this way:

A          R RCONVTXT                                            
A            TEXT         100A         COLHDG('Text')            
A            TEXT2B       100G         COLHDG('Text')            
A                                      CCSID(1200 *NOCONVERT)    

I'm working with characters in polish language stored in the "TEXT" field.

If I use this code in my rpgle program:

exec sql                                           
   UPDATE CONVTXT set TEXT2B =                    
   CAST(CAST(TEXT as char(100) CCSID 65535)       
   AS CHAR(100) CCSID 870);                        

all the text in first field "TEXT" is converted perfectly and updated in the other field in unicode.

But if the text that I want to convert is in a text field (100c), how can I convert it using SQL?

Answer 1

RPG will automatically convert between CCSID's. This is all it takes:

**free
dcl-s ucs2str     Ucs2(100) Inz('this is a test');
dcl-s charstr     Varchar(100) Inz('');

charstr = ucs2str;

Here is a memory dump of ucs2str :

Here is a memory dump of charstr after the assignment:

---

Here is a little more info on this topic. TL/DR The following code works, and just a side note, our system is set to CCSID 65535. That isn't necessarily a good choice, it is just the way things are.

exec sql
  create table jmmlib/mytable
    (charfld   Char(100) ccsid 37,
     ucs2fld   NChar(100));

exec sql
  insert into jmmlib/mytable
    values('Constant Test', 'Constant Test'),
          (:ucs2str, :ucs2str),
          (:charstr, :ucs2str);

exec sql
  declare c1 cursor for
    select cast(ucs2fld as char(100) ccsid 37), charfld from jmmlib/mytable;

exec sql
  open c1;

exec sql
  fetch c1 into :ucs2str, :charstr;    ((1))

exec sql
  fetch c1 into :charstr, :ucs2str;    ((2))

exec sql
  fetch c1 into :ucs2str, :charstr;    ((3))

exec sql
  close c1;

So here things are a bit jumbled to help keep things seperate. I wouldn't necessarily code it this way normally. The table columns are in the following order (UCS2, CHAR). The fetch columns are in the following order (CHAR, UCS2).

First look at the insert. I can insert constants in each of the fields, and the character sets are converted properly. I can insert a UCS2 string into either the UCS2 field or the CHAR field. But, I can only insert the CHAR field into the CHAR field. There appears to be some issue with converting between 65535 and UCS2. I believe that this is an issue for me because our box has the QCCSID system value set to 65535. This is true even though the default CCSID for our jobs is 37. I do not think this would be an issue if QCCSID was set some other way.

Next look at the declaration for cursor C1 . I have cast UCS2FLD to CCSID 37. This is the only way I could get FETCH ((2)) to work. This was that conversion issue again. CCSID 37 can likely be put into a 65535 field because it is an EBCDIC CCSID, so the field is still EBCDIC, even though no conversion happens, and RPG is ok with that (or SQL since it was an SQL error message). But it can't put UCS2FLD into an EBCDIC field without converting it first, and it can't convert from UCS2 to CCSID 65535. Once again, I don't think this would be a problem if we weren't using CCSID 65535.

Answer 2

Are you asking how you use an RPG defined variable in embedded SQL?

If so, the answer is fairly simple. You simply need to put a leading ':' in front of the RPG variable in the SQL statement.

Dcl-S Text Char(100) Inz('blah');

Exec Sql                                           
   Update ConvTxt Set Text2B =                    
   Cast(Cast(:Text As Char(100) CCSID 65535)       
   As Char(100) CCSID 870); 

Also, you can set a character string to a particular CCSID using the following which may be an even better solution to your problem.

Dcl-S Text Char(100) CCSID(870) Inz('blah');

Exec Sql                                           
   Update ConvTxt Set Text2B = :Text;