Perl-基于哈希过滤器创建哈希数组

Question

I have this hash that contains some information:

my %hash = (
    key_1 => {
        year => 2000,
        month => 02,
    }, 
    key_2 => {
        year => 2000,
        month => 02,
    }, 
    key_3 => {
        year => 2000,
        month => 03,
    }, 
    key_4 => {
        year => 2000,
        month => 05,
    }, 
    key_5 => {
        year => 2000,
        month => 01,
    }
);

I wan't to create an array of hashes in which each of the array elements, lists every single hash key/value pairs that has the same year and month.

So basically I want to create something like this:

$VAR1 = [
    'key_1' => {
        'month' => 2,
        'year' => 2000
    },
    'key_2' => {
        'month' => 2,
        'year' => 2000
    }
], [
    'key_3' => {
        'month' => 3,
        'year' => 2000
    }
], [
    'key_4' => {
        'month' => 3,
        'year' => 2000
    }
], [
    'key_5' => {
        'year' => 2000,
        'month' => 1
    }
];

The real question here is: How can I compare a hash key key value's to other key key value's and make a map out of it.

Thank you for your time! =)

Answer 1

I'm getting a slightly different results - key_3 and key_4 should belong to the same group.

my %by_year_and_month;
undef $by_year_and_month{ $hash{$_}{year} }{ $hash{$_}{month} }{$_}
    for keys %hash;

my $result;
for my $year (keys %by_year_and_month) {
    for my $month (keys %{ $by_year_and_month{$year} }) {
        push @$result, [ map { $_ => { month => $month, year => $year } }
                         keys %{ $by_year_and_month{$year}{$month} } ];
    }
}

Answer 2

my %hash = (
    key_1 => {year => 2000, month => 02},
    key_2 => {year => 2000, month => 02},
    key_3 => {year => 2000, month => 03},
    key_4 => {year => 2000, month => 03},
    key_5 => {year => 2000, month => 01}
);
my @v=qw(year month);             # keys compared
my @k=sort keys %hash;
my(@a,%i);
push@{$a[sub{$i{join$;,map$_[0]{$_},@v}//=@a}->($hash{$_})]},($_=>$hash{$_}) for@k;
use Data::Dumper; print Dumper(\@a);

Answer 3

You say you want the following, but it makes no sense.

 $VAR1 = [$k,$v,$k,$v...], [...], [...], ...;

---

The accepted answer assumed you meant you want the following:

$VAR1 = [ [$k,$v,$k,$v,...], [...], [...], ... ];

That can be obtained as follows:

sub group_id { sprintf "%04d-%02d", @{ $_[0] }{qw( year month )} }

my %grouped;
for my $k (keys(%hash)) {
   my $v = $hash{$k};
   push @{ $grouped{ group_id($v) } }, $k, $v;
}

my $VAR1 = [ map { $grouped{$_} } sort keys %grouped ];

---

But that's a very weird format. The following would make far more sense:

$VAR1 = [ { $k=>$v,$k=>$v,...}, {...}, {...}, ... ];

That can be obtained as follows:

sub group_id { sprintf "%04d-%02d", @{ $_[0] }{qw( year month )} }

my %grouped;
for my $k (keys(%hash)) {
   my $v = $hash{$k};
   $grouped{ group_id($v) }{$k} = $v;
}

my $VAR1 = [ map { $grouped{$_} } sort keys %grouped ];

---

In both cases, the key is to use a hash to group similar things.

In both cases, the resulting groups are ordered chronologically.