如果单元格值包含在另一个工作表中，则为Excel vba

Question

I have worksheets called '1Q FY 18' which is the second sheet and 'Holiday' which is the 7th sheet.

The row 12 of '1Q FY 18' contains dates from 4/1 to 6/30. And the cells from 'B20' to 'B35' contains holidays of 2018.

I would like to highlight columns in the second sheet that have matching value at range("B20:B35"). In other words, I would like to color the columns that is holiday.

My code was like this.

   Sub Holiday()
    lastr = Worksheets(2).UsedRange.Rows.Count
    lastc = Worksheets(2).UsedRange.Columns.Count
    Worksheets(2).Activate
    Set ws7 = Worksheets("Holiday")
    Set rng1 = ws7.Range("B20:B35")
    For i = 15 To lastc
    If Not IsEmpty(Application.WorksheetFunction.VLookup(Cells(12, i).Value, rng1, 1)) Then
    Range(Cells(13, i), Cells(lastr - 2, i)).Interior.ColorIndex = 6
    End If
    Next i
    End Sub

But error occurs with this one. When I debug, it highlights

****If Not IsEmpty(Application.WorksheetFunction.VLookup(Cells(12, i).Value, rng1, 1)) Then****

What do I do?

Answer 1

Here is a simple macro that does what you describe. I've placed a .select statement in it so you can step through the code to see how it works, but you should remove it after that. Once you understand how it works you can change to suit your needs. Let me know if you have questions. The animated gif shows each sheet of the workbook and then the macro running. In my example I've just chosen every week for the holidays, but you can change that. I also included a sub to reset the colors conveniently. (You say you want to "color the columns" but I just colored the cells. If you really want to color the whole column you would replace cell.interior .. and r.interior ... with Columns(cell.Column).interior ...)

Sub test()
Dim sh1 As Worksheet, sh2 As Worksheet
Dim r1 As Range, r2 As Range, cell As Range, holidayCell As Range
Set sh1 = Worksheets("1Q FY 18")
Set sh2 = Worksheets("Holiday")
Set r1 = sh1.Range("A12")
Set r1 = sh1.Range(r1, r1.End(xlToRight))
Set r2 = sh2.Range("B20:B35")
resetColor r1
For Each cell In r1
  cell.Select
  For Each holidayCell In r2
    If cell = holidayCell Then
      cell.Interior.Color = vbYellow
      Exit For
    End If
  Next
Next cell
End Sub

Sub resetColor(r As Range)
    With r.Interior
        .Pattern = xlNone
        .TintAndShade = 0
        .PatternTintAndShade = 0
    End With
End Sub