如何获取日期范围之间的天数

Question

I currently have the following Array formula getting the frequency of days per Fleet Number(this is over all and not linked to any date):

=SUM(IF(FREQUENCY(IF('Management Ops Sheet'!$B$8:$B$500=A6,'Management Ops Sheet'!$A$8:$A$500),'Management Ops Sheet'!$A$8:$A$500)>0,1))

Below is a breakdown of what each part represents :

'Management Ops Sheet'!$B$8:$B$500 is the list of Fleet numbers

A6 is the fleet number im checking for

'Management Ops Sheet'!$A$8:$A$500 is the list of dates

I have a date range I want to work from:

Cell B3 is the Date From

Cell C3 is the Date To

What I want to do is get the frequency of the days between(and including) the above dates.

Below is the data I am searching through:

| Date      | Fleet No. |   |   |   |
|-----------|:---------:|---|---|---|
| 01-Mar-18 | H05       |   |   |   |
| 01-Mar-18 | H05       |   |   |   |
| 01-Mar-18 | H05       |   |   |   |
| 01-Mar-18 | H05       |   |   |   |
| 01-Mar-18 | H72       |   |   |   |
| 01-Mar-18 | H72       |   |   |   |
| 01-Mar-18 | H77       |   |   |   |
| 01-Mar-18 | H86       |   |   |   |
| 02-Mar-18 | H05       |   |   |   |
| 02-Mar-18 | H72       |   |   |   |
| 03-Mar-18 | H77       |   |   |   |
| 03-Mar-18 | H86       |   |   |   |
| 04-Apr-18 | H86       |   |   |   |

Below is where I am using the formula:

| Month:    |          2018-02-01      |     2018-03-01       |                   |   |
|-----------|:------------------------:|----------------------|-------------------|---|
| TOTAL     |  R           56,043.50   | 6745                 | 2.25              |   |
| Fleet No. | Turnover   Month to Date | KM's   Month to Date | Days   Worked M/D |   |
| H05       |  R             3,097.50  | 645                  | 2                 |   |
| H72       |  R           19,864.00   | 2200                 | 2                 |   |
| H77       |  R           20,132.00   | 1400                 | 2                 |   |
| H86       |  R           12,950.00   | 2500                 | 3                 |   |
|           |                          |                      |                   |   |
|           |                          |                      |                   |   |
|           |                          |                      |                   |   |
|           |                          |                      |                   |   |
|           |                          |                      |                   |   |
|           |                          |                      |                   |   |
|           |                          |                      |                   |   |

I dont know how to change the formula to get this to work. If any one is able to help I would greatly appreciate it!

Thanks!!

Answer 1

I finally got it sorted out!! Thanks to @Luuklag and @QHarr that tried helping me out.

The formula I landed up using was as follows:

=IF(A6<>"",SUM(IF(FREQUENCY(IF(MONTH('Management Ops Sheet'!$A$8:$A$500)>=MONTH(B$3),IF(MONTH('Management Ops Sheet'!$A$8:$A$500)<=MONTH(C$3),IF('Management Ops Sheet'!$B$8:$B$500=A6,IF('Management Ops Sheet'!$A$8:$A$500<>"",MATCH('Management Ops Sheet'!$A$8:$A$500,'Management Ops Sheet'!$A$8:$A$500,0))))),ROW('Management Ops Sheet'!$A$7:$A$500)-ROW('Management Ops Sheet'!$A$7)+1),1)),"")

Please note that this is an Array Formula, so you need to push Ctrl + Shift + Enter for this formula to work.

The following post actually helped me in the right direction: Click Here