将小于筛选器添加到Excel VBA中的数据透视表

Question

I'm trying to add a filter to a column in a pivot table whenever a worksheet is activated in Excel.

I have the following so far:

   Dim pvt As PivotTable
   Dim pvtField As PivotField

   Set pvt = ActiveSheet.PivotTables("MyPivotTable")
   Set pvtField = pvt.PivotFields("MyPivotColumnTopField")

   'First refresh the table
   pvt.RefreshTable

   'Clear Out Any Previous Filtering
   pvtField.ClearAllFilters

   'Add the less than filter
   pvtField.PivotFilters.Add xlValueIsLessThan, Value1:="1000"

But I get an Invalid Procedure call or argument error on the line that is trying to add the filter.

I've also tried:

   pvtField.PivotFilters.Add(xlValueIsLessThan, Value1:="1000")

but get a syntax error with that.

I'm looking at the documentation at https://msdn.microsoft.com/en-us/vba/excel-vba/articles/pivotfilters-add-method-excel but cannot figure it out.

Answer 1

You're using .Add but you should be using .Add2 as per that link.

pf.PivotFilters.Add2 Type:=xlCaptionIsLessThan, Value1:=1000

(I note that link has the correct syntax at the top, but the incorrect syntax at the bottom).

Normally the easiest way to troubleshoot syntax like this is to fire up the Macro recorder, perform your actions manually, then inspect the code. In this case, that's problematic. For instance, if I start with the PivotTable shown below right:

...and then clear all filters before setting a Label filter:

...then I get the exact result I want:

...and I get the following code:

Sub Macro6()

    ActiveSheet.PivotTables("PivotTable1").PivotFields("Test").ClearAllFilters
    ActiveSheet.PivotTables("PivotTable1").PivotFields("Test").PivotFilters.Add2 _
        Type:=xlCaptionIsLessThan, Value1:="11"
End Sub

But weirdly when I run that code, I get this:

Despite the fact that the Macro Recorder spits out code with the 11 in a string ie "11", you don't want to feed in a string. Why the Macro Recorder would tell you otherwise is beyond me.

Answer 2

Based on @jeffreyweir's answer (which did a string based filter for me), here is a working example of using .Add2 with both a string based filter and a numerical filter.

This is my example table and pivot table:

And this is code I have behind each button:

Sub Button1_Click()
Dim pf As PivotField

    Set pf = ActiveSheet.PivotTables("PivotTable1").PivotFields("Numbers")
    pf.ClearAllFilters
    pf.PivotFilters.Add2 Type:=xlCaptionIsLessThan, Value1:="11"
End Sub

Sub Button2_Click()
Dim pf As PivotField

    Set pf = ActiveSheet.PivotTables("PivotTable1").PivotFields("Numbers")
    pf.ClearAllFilters
    pf.PivotFilters.Add2 Type:=xlCaptionIsLessThan, Value1:=11

End Sub

Sub Button3_Click()
Dim pf As PivotField

    Set pf = ActiveSheet.PivotTables("PivotTable1").PivotFields("Numbers")
    pf.ClearAllFilters
End Sub

Note that:

• Button1 is the Show < "11" button which does a string based filter
• Button2 is the Show < 11 button which does a numeric filter
• Button3 is the Show All button which removes the filter

When I click the Show < "11" button (ie Button1) I get the following result:

When I click the Show < 11 button (ie Button2) I get the following (desired) result: