VBA Excel 选择命名范围内的一系列单元格

Question

I have a Named Range col_9395 it is an entire column. I want to set a range within this Named range. I want the range to start at row 3 to row 200 of same column. Whats the best way to do this?

Original working line without Named Range:

Set rngBlnk = Sheet108.Range("T3:T200").SpecialCells(xlCellTypeBlanks)

This is the code I tried with no luck:

Set rngBlnk = Range("col_9395)(3,1):Range("col_9395)(200,1).SpecialCells (xlCellTypeBlanks)

Answer 1

You can see the sort of logic with

Option Explicit

Sub test()

Dim colToUse As Long
colToUse = ThisWorkbook.Worksheets("Sheet1").Range("ol_9395").Column

With ThisWorkbook.Worksheets("Sheet1")
Debug.Print .Range(.Cells(3, colToUse), .Cells(200, colToUse)).Address
End With

End Sub

Answer 2

Sub t()
Dim rng As Range
Set rng = Range("col_9395") ' for easier use

Dim blnkRng As Range
Set blnkRng = Range(Cells(rng.Rows(3).Row, rng.Column), Cells(rng.Rows(200).Row, rng.Column)).SpecialCells(xlCellTypeBlanks)
blnkRng.Select
End Sub

What I did was assign your named range to a variable (just for easier referencing). Then using the Range() property, I used the 3rd and 200th row of your named range to set the range to look for blank cells.

The idea is that this will help you in the event your named range isn't simply an entire column. It will get the relative 3rd and 200th row from your named range.

Answer 3

Option Explicit

Public Sub TestMe()

    Dim rngBlnk As Range

    Dim firstCell As Range
    Dim lastCell As Range

    Set firstCell = [col_9395].Cells(3, 1)
    Set lastCell = [col_9395].Cells(200, 1)

    If WorksheetFunction.CountBlank(Range(firstCell, lastCell)) > 0 Then
        Set rngBlnk = Range(firstCell, lastCell).SpecialCells(xlCellTypeBlanks)
    End If   

End Sub

A kind of a problem with SpecialCells and assigning to them is that if there are no cells from the specific type, it throws an error.

Thus, there is a check with WorksheetFunction.CountBlank()>0 , before the setting of rngBlnk to the special cells.

Answer 4

Might be wrong, but I find this the easiest one:

Private Sub Test()
    Dim rngBlnk As Range
    Set rngBlnk = Range("col_9395").Rows("3:200").SpecialCells(xlCellTypeBlanks)
End Sub

Answer 5

I'm late to the party, I know, but maybe this will help someone. I've stumbled on a technique that I don't see presented as an option in any of the handful of "range-in-a-range" questions here.

I discovered you can ask VBA for a range of a range directly. I have formatted some data as a Table, but it could be simply a Named Range, or even an unnamed range I suppose. My code that is working looks like this:

        With Workbooks(Filename)
            .Worksheets(tabName).Activate
            .Worksheets(tabName).Range("SummaryBand").Range("B2:R2").Copy
            End With

My Table is named SummaryBand, which due to a previous step was not necessarily always in the same absolute position on the spreadsheet, but I wanted an absolute Range within SummaryBand. In this example, "B2:R2" is the absolute position within the Table, with the top left cell of the Table being A1.