如何使用自动快捷键获取textarea文本值？

Question

I am trying to format my java code with https://www.tutorialspoint.com/online_java_formatter.htm . But I have an issue with getting text from textarea.I am trying to get text from following textarea.

<textarea class="ace_text-input" style="width: 6.59px; height: 14.05px; right: 428.4px; bottom: 511.79px; opacity: 0;" spellcheck="false" wrap="off"></textarea>

Autohotkey code:

;code beautifier java
^+b::
Send ^c
formatter := "https://www.tutorialspoint.com/online_java_formatter.htm"
(pwb2 := ComObjCreate("InternetExplorer.Application")).Visible:=True
pwb2.navigate(formatter)
while pwb2.busy
    sleep 15

pwb2.document.getElementsByTagName("textarea")[0].value=Clipboard
pwb2.document.getElementById("beautify").Click()
sleep 5000
Clipboard := pwb2.document.getElementsByTagName("textarea")[1].innerHTML
Send, ^v
pwb2.quit()
Return

Answer 1

The problem is that the website you're using to format the code doesn't use a plain <textarea> , but rather this code editor . If you look at the JavaScript near the bottom of the site's source you can see that there's two of these editors being used ( editor and outputeditor ). Their setValue and getValue methods can be used to work with their contents.

To do this in AHK, you can make an element in the page whose content will hold the clipboard data and later the result of the formatting. pwb2.document.parentWindow.execScript can be used to execute the JavaScript for interacting with the editors using the data from the clipboard element.

^+b::
Clipboard := ""
Send {Ctrl Down}c{Ctrl Up}
ClipWait 1
if ErrorLevel {
    MsgBox Java formatter error: Clipboard is empty
    return
}
java := Clipboard

formatter := "https://www.tutorialspoint.com/online_java_formatter.htm"
pwb2 := ComObjCreate("InternetExplorer.Application")
pwb2.navigate(formatter)
while pwb2.busy
    sleep 15

d := pwb2.document
ahkData := d.createElement("div")
ahkData.id := "ahkData"
ahkData.hidden := true
ahkData.innerText := java
d.body.appendChild(ahkData)

js =
(
    var ahkData = document.getElementById('ahkData');
    var marker = "//AHKDATA\n";
    editor.setValue(marker + ahkData.innerText);
    outputeditor.on("change", function(e) {
        var value = outputeditor.getValue();
        if (value.indexOf(marker) !== -1) {
            ahkData.innerText = value.substring(marker.length);
            ahkData.hidden = false;
        }
    });
    document.getElementById("beautify").click();
)

d.parentWindow.execScript(js)

while ahkData.hidden
    sleep 150

Clipboard := ahkData.innerText
Send ^v
pwb2.quit()
Return

Note that the click handler for the beautify button returns before outputeditor is updated because it just sends an asynchronous POST request with the unformatted code, so I added a callback to outputeditor 's change event which will run when the request finishes and updates the editor. marker in this callback serves to differentiate the outputeditor change events that occur because of the code initially included on the website from those that occur after formatting our code. I assumed you don't want to see the IE window and removed its visibility, but if you did want it visible you'll need to use WinWaitActive or something similar to wait for the IE window to close and the previous (copied-from) window to become active again before sending Ctrl + v .

Since the formatting is really done through a POST request, you could instead use the WinHttp.WinHttpRequest.5.1 COM object to replicate the request. However, IMO it's more cumbersome (in AHK at least) since you'll have to manually encode the Java code in the clipboard.