如何使用 CMake 从 qmake 获取 model OTHER_FILES？

Question

In qmake based projects, it's possible to include OTHER_FILES to use them in QtCreator, eg

QT += core gui widgets
TARGET = example-program
TEMPLATE = app

HEADERS = mainwindow.h
SOURCES = main.cpp mainwindow.cpp

OTHER_FILES = README.md LICENCE examples/network/server.c

That way one can access README.md within QtCreator easily. A CMake file with the same target looks like

cmake_minimum_required(VERSION 3.5)
project(example CXX)

set(CMAKE_AUTOMOC ON)

find_package(Qt5 COMPONENTS Core Gui Widgets REQUIRED)

set(HEADERS mainwindow.h)
set(SOURCES main.cpp mainwindow.cpp)
set(OTHER_FILES README.md LICENCE examples/network/server.c)

add_executable(example-program ${SOURCES} ${HEADERS})
target_link_libraries(example-program Qt5::Core Qt5::Gui Qt5::Widgets)

However, the OTHER_FILES aren't shown in QtCreator and I have to access them via "File > Open" instead of the project browser. Is there a workaround?

Answer 1

There's no problem with adding non-compiled files as the sources of a CMake target; CMake will simply ignore them if it doesn't recognise their extension. So you can easily do this:

add_executable(example-program ${SOURCES} ${HEADERS} ${OTHER_FILES})

With files which could be confused for actual sources (based on their extension), there's always the option of setting their HEADER_FILE_ONLY property to true:

set_source_files_properties(
  ${OTHER_FILES}
  PROPERTIES
  HEADER_FILE_ONLY TRUE
)

Answer 2

You can use a custom target that depends on the given files:

add_custom_target(project-related-files SOURCES ${OTHER_FILES})

Since the COMMAND is missing, an empty target will be generated, but it will still depend on the SOURCES . This is also the official way to include other files into an IDE:

SOURCES
Specify additional source files to be included in the custom target. Specified source files will be added to IDE project files for convenience in editing even if they have no build rules.

Answer 3

I'll comment that I think both answers are correct, which to use depends on the particulars of the project.

Angew's answer adds the files to a single project, within the project.

In my case, Zeta's answer worked better, as I had files at the top-level of a project with subprojects, and having a new folder (with a name I could customize) in QtCreator better fit my needs.

Adding an additional answer, as I didn't see the differences between the two approaches mentioned.