F＃类型匹配-无法创建地图或匹配记录

Question

I have tried to adapt a WikiBooks example to accept csv input and types but am struggling with converting the incoming type list to a dictionary and matching user inputs.

// https://en.wikibooks.org/wiki/F_Sharp_Programming/Sets_and_Maps#Examples_2

module SOQN = 

   open System
   open FSharp.Data

   type Country = Country of string
   type City = City of string
   type CountryCapital = {
      Country:Country
      City:City 
    }
   let [<Literal>] sampleCsv  = @"D:\Country_Capitals.csv"
   type Capitals = CsvProvider<sampleCsv, Separators=",", HasHeaders=true>

   let readFromCsvFile (fileName:string) = 
      let data = Capitals.Load(fileName)
      [ for row in data.Rows do
           yield { Country = Country row.Country; City = City row.City; } ]        
   let countryCapitals = 
      readFromCsvFile sampleCsv
   // ->     |> Map.ofList

   Console.Write("Find capital by country (type 'q' to quit): ")
   match Console.ReadLine() with
   | "q" -> Console.WriteLine("Bye!")
   | country ->
      match countryCapitals with
      // ->     | { Country = country } -> Console.WriteLine("Capital of {0} is {1}\n", country, capital)
      | _ -> Console.WriteLine("Country not found.\n")

  // Expected Output: Find capital by country (type 'q' to quit): Egypt
  //                  Capital of Egypt is Cairo

What am I missing?

Answer 1

You need to use a tuple to create the Map from the List , so you don't really need the record type at all. Then, you will want to match on Map.tryFind of the input country. Here's an example using the tuple and Map.tryFind . The only other changes I made were to use printfn instead of Console.WriteLine and to simplify your list-generating expression:

open System
open FSharp.Data

let [<Literal>] sampleCsv  = @"D:\Country_Capitals.csv"
type Capitals = CsvProvider<sampleCsv, Separators=",", HasHeaders=true>

let readFromCsvFile (fileName:string) = 
    let data = Capitals.Load(fileName)
    [ for row in data.Rows -> (row.Country, row.City) ]    

let countryCapitals = 
    readFromCsvFile sampleCsv
    |> Map.ofList

printfn "Find capital by country (type 'q' to quit): "

match Console.ReadLine() with
| "q" -> printfn "Bye!"
| country ->
    match countryCapitals |> Map.tryFind country with
    | Some capital -> printfn "Capital of %s is %s" country capital
    | _ -> printfn "Country not found."

EDIT To show continued use of record type:

open System
open FSharp.Data

type CountryCaptial = { Country: string; Capital: string }

let [<Literal>] sampleCsv  = @"D:\Country_Capitals.csv"
type Capitals = CsvProvider<sampleCsv, Separators=",", HasHeaders=true>

let readFromCsvFile (fileName:string) = 
    let data = Capitals.Load(fileName)
    [ for row in data.Rows -> { Country = row.Country; Capital = row.City } ]    

let countryCapitals = 
    readFromCsvFile sampleCsv
    |> List.map (fun c -> c.Country, c)
    |> Map.ofList

printfn "Find capital by country (type 'q' to quit): "

match Console.ReadLine() with
| "q" -> printfn "Bye!"
| country ->
    match countryCapitals |> Map.tryFind country with
    | Some countryCapital -> printfn "Capital of %s is %s" countryCapital.Country countryCapital.Capital
    | _ -> printfn "Country not found."