无法使用批处理文件将文件移动到文件夹中

Question

i am trying to create folders using part of the file name (the first 10 digits unique digits) and then move the files to respective folders. I am able to create the folders but for some reason, unable to move the files into the folder. Any idea why? Here is my code:

@echo off
for /f %%a in ('dir /a-d /b') do (
  if not "%%~dpnxa"=="%~dpnx0" call :func "%%~a"
)
goto :EOF
:func
set file=%~1
set dir=%file:~0,10%
md "%dir%" 2>nul
move "%file%" "%dir%" 
goto :EOF

Answer 1

It works, but not if your filenames have spaces in them, it will still create most or entire folder, depending on where the spaces are, but not move the file..

So to rectify this try adding "delims=" to the for loop to skip default delimiters by default being whitespace.

@echo off
for /f "delims=" %%a in ('dir /a-d /b') do (
  if not "%%~dpnxa"=="%~dpnx0" call :func "%%~a"
)
goto :EOF
:func
set file=%~1
set "dir=%file:~0,10%"
md %dir% 2>nul
move "%file%" "%dir%"

Answer 2

Although it seems odd, you can use RoboCopy to 'move' files too. The following example uses the Where command to select only files which contain at least 10 characters, (this means that you can keep your script name to less than 10 characters and you won't need to filter it) :

@Echo Off
SetLocal EnableDelayedExpansion
For /F "Delims=" %%A In ('Where .:??????????*.*') Do (Set "FN=%%~nA"
    RoboCopy . "!FN:~,10!" "%%~nxA" /Mov>Nul)

Please bear in mind that this doesn't prevent directories being created which end with spaces, ie the 10th character of the filename is a space , which could cause you problems later!