遍历Instr Excel VBA

Question

I'm trying to match names on sheet1 with sheet2 but the code below ain't working. All I want to do is to match(by coloring blue) if the name on sheet1 contains at least part of the name on sheet2. Say for example;

sheet1: John Livingtone

sheet2 : John Living

Sub inst()

    Dim nameone As Variant
    Dim cel As Variant
    Dim nametwo As Variant
    Dim cem As Variant

    nameone = Sheets("Sheet1").Range("L1:L1600")
    nametwo = Sheets("sheet2").Range("M1:M1600")

    For Each cem In nameone

        For Each cel In nametwo

            If InStr(cem.Value, "cel.Value") > 0 Then
                cem.Value = RGB(0, 0, 255)
            End If

        Next cel

    Next cem

Answer 1

If you set your variables to ranges and actually count the rows instead of hard coding the number of rows, the code would work faster as well.

Your question shows that sheet2 has the partial string, but your code shows the opposite. I ran the loop according to the code you provided.

Sub inst()

    Dim nameone As Range
    Dim cel As Range
    Dim nametwo As Range
    Dim cem As Range
    Dim sh1 As Worksheet, sh2 As Worksheet
    Dim L1 As Long, L2 As Long

    Set sh1 = Sheets("Sheet1")
    Set sh2 = Sheets("Sheet2")

    With sh1
        L1 = .Cells(.Rows.Count, "L").End(xlUp).Row
        Set nameone = .Range("L1:L" & L1)
    End With

    With sh2
        L2 = .Cells(.Rows.Count, "M").End(xlUp).Row
        Set nametwo = .Range("M1:M" & L2)
    End With



    For Each cem In nameone.Cells
        For Each cel In nametwo.Cells

            If InStr(cem.Value, cel.Value) <> 0 Then
                cem.Font.Color = RGB(0, 0, 255)
            End If

        Next cel

    Next cem
End Sub

If you wanted the cell to be blue and not the font, then change the interior color

 cem.Interior.Color = RGB(0, 0, 255)