发送JSON内容类型的POST请求并在VB.NET中显示JSON响应

Question

I am trying to send a POST request to shapeshift which has few parameters to be sent as JSON and then wish to display part of the response in VB.NET

Documentation from shapeshift: https://info.shapeshift.io/api#api-9

Below is what I have tried until now:

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click

    Dim request As HttpWebRequest
    Dim response As HttpWebResponse
    Dim reader As StreamReader
    Dim rawresponse As String

    Try

        request = DirectCast(WebRequest.Create("https://shapeshift.io/sendamount"), HttpWebRequest)
        request.ContentType = "application/json"
        request.Method = "POST"

        Dim postdata As String = "{""amount"":}" + TextBox1.Text + "{,""withdrawal"":}" + TextBox2.Text + "{,""pair"":""btc_eth""}" + "{,""returnAddress"":}" + TextBox3.Text
        request.ContentLength = postdata.Length

        Dim requestWriter As StreamWriter = New StreamWriter(request.GetRequestStream())
        requestWriter.Write(postdata)
        requestWriter.Close()

        response = DirectCast(request.GetResponse(), HttpWebResponse)
        reader = New StreamReader(response.GetResponseStream())


        rawresponse = reader.ReadToEnd()

   Catch ex As Exception
        Console.WriteLine(ex.ToString)
   End Try

   Dim json As String = rawresponse
   Dim jsonObject As Newtonsoft.Json.Linq.JObject = Newtonsoft.Json.Linq.JObject.Parse(json)

   Label1.Text = jsonObject("expiration").ToString

End Sub

ERROR I get is: 400 Bad Request

I think its because I have messed up something in code where JSON POST request is explained. I did a lot of research and tried few things but nothing worked :(

Answer 1

Try this instead:

Dim postdata As String = "{""amount"":" + TextBox1.Text + "},{""withdrawal"":""" + TextBox2.Text + """},{""pair"":""btc_eth""},{""returnAddress"":""" + TextBox3.Text + """}"

Your data was malformed.

Or here is another version with String.Format:

Dim postdata2 As String = String.Format("{{""amount"":{0}}},{{""withdrawal"":""{1}""}},{{""pair"":""btc_eth""}},{{""returnAddress"":""{2}""}}", TextBox1.Text, TextBox2.Text, TextBox3.Text)

Answer 2

WebRequest is pretty old now. You may want to use the newer System.Net.Http.HttpClient, official docs are here .

Also when transforming to Json, I massively recommend using the Newtonsoft.Json nuget package's JConvert / Deserialize features with generic arguments (Of ...) to convert to a predefined object. Saves a lot of manual text parsing on the return.

Have mocked up a quick example:

Private async Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click

    Dim transaction As New MyRequestData With 
    {
        .Amount = Convert.ToDecimal(TextBox1.Text),
        .Withdrawal = Convert.ToDecimal(TextBox2.Text),
        .ReturnAddress  = TextBox3.Text
    }

    Dim content = newtonsoft.Json.JsonConvert.SerializeObject(transaction)
    dim buffer = System.Text.Encoding.UTF8.GetBytes(content)
    Dim bytes = new Net.Http.ByteArrayContent(buffer)
    bytes.Headers.ContentType = new Net.Http.Headers.MediaTypeHeaderValue("application/json")

    Dim responseBody As string = nothing
    Using client As New System.Net.Http.HttpClient
        Dim response = Await client.PostAsync("https://shapeshift.io/sendamount",bytes)
        responsebody = Await response.Content.ReadAsStringAsync()
    End Using

    Dim data = Newtonsoft.Json.JsonConvert.DeserializeObject(Of MyResponseData)(responsebody)

    If data.Expiration Is Nothing
        Label1.Text = data.Error
    Else
        Label1.Text = data.Expiration
    End If
End Sub

Public class MyRequestData
    Public property Amount As Decimal
    Public property Withdrawal As Decimal
    Public property Pair As String = "btc_eth"
    Public property ReturnAddress As String
End Class

Public class MyResponseData
    Public property Expiration As String
    Public property [Error] As String
End Class

Hope this helps, good luck!