如何在netstat命令中传递参数？

Question

I am using a netstat command in VBScript to find out the ports which are listening. As a process, I am reading the IP address and port number from two variables.

A file contains an IP address, port number which were separated by commas as shown below:

10.x.x.x,3389

Like there are multiple IPs and port numbers existing in a file. By using array concept I am fetching the IP address and port number from the file using myarray(0) and myarray(1) variables.

My code looks like this:

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objShell = WScript.CreateObject("WScript.Shell")

Dim port_number, port_status, port_conn_ip, portread, portfile, PSExec, PCIExec

objShell.CurrentDirectory = "C:\Program Files (x86)\GnuWin32\bin"

Set objfile = objFSO.openTextFile("C:\IBM\port_mon\list_of_ports.txt")

Do until objFile.AtEndOfStream
    portread = objfile.ReadLine
    portfile = Split(portread, ",")

    Set PSExec = objShell.Exec("%comspec% /k ""netstat -an |find ""myvalue(0) ""|find ""myvalue(1)""|awk ""{print $4}""""")

    port_status = PSExec.Stdout.ReadLine

    WScript.Echo port_status

But here myvalue(0) and myvalue(1) are not updating with IP address or port number. I also tried to provide like " & myvalue(0) & " but this also didn't give me any result. Always the output is empty.

As a background work, I have verified the connectivity of IP address and port number both are in connected and established state.

Answer 1

The string concatenation approach was the right thing to do. VBScript doesn't expand variables inside strings. However, the name of your array variable is portfile , not myvalue (or myarray ). Put Option Explicit at the beginning of your script to detect mistakes like that.

Change your code to something like this, and it should do what you expect:

cmd = "%comspec% /k ""netstat -an | find """ & portfile(0) & """ | find """ & _
      portfile(1) & """ | awk ""{print $4}"""""
Set PSExec = objShell.Exec(cmd)

BTW, you don't need to call find twice for address and port (assuming that both refer to a remote host). Just filter for IP:port :

cmd = "%comspec% /k ""netstat -an | find """ & portfile(0) & ":" & _
      portfile(1) & """ | awk ""{print $4}"""""
Set PSExec = objShell.Exec(cmd)

And as I mentioned in the comments to your previous question, you also don't need to print a column with awk and then read and compare the output. Just use the Run method, add another find step to check if the line contains the text "ESTABLISHED", and then check the exit code of the command.

cmd = "%comspec% /c ""netstat -an | find """ & portfile(0) & ":" & _
      portfile(1) & """ | find ""ESTABLISHED"""""
rc = objShell.Run(cmd, 0, True)

If rc = 0 Then
    'connection established
Else
    'no established connection found
End If