使用vba在excel范围内查找特定行

Question

I need to find rows on a sheet that meet given criteria(s). I saw several times that authors perform this by filtering based on the search criteria but I don't like this method, so I am using something like this.

Sub fi()
    Dim lastRow As Long
    lastRow = 100
    Dim myRow As Long
    For i = 1 To lastRow
        If Cells(i, 1) = "value1" And Cells(i, 3) = "value2" And Cells(i, 4) = "value3" Then
            i = myRow
        End If
    Next i
End Sub

Does any of you have some good practice to do it on more efficient way? These are a kind of orders with 10 cells by row, but I can find what I need based on three of them. It is s typical sql select statement, but here I cannot use sql. thanks

Answer 1

You could use the following approach with ADODB

Option Explicit

Sub ReadFromWorksheetADO()
Dim conn As New ADODB.Connection

    ' Assuming there is no header 
    conn.Open "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" _
              & ThisWorkbook.FullName & ";Extended Properties=""Excel 12.0;HDR=NO;"";"

    Dim query As String
    ' The sheet with the data should have the name Sheet1
    ' query = "Select * From [Sheet1$]"
    query = "Select F1,F2,F3 From [Sheet1$]"

    Dim rs As New ADODB.Recordset
    rs.Open query, conn
    rs.Filter = "F1='value1' AND F2 ='value2' AND F3 ='value'"

    ' Add a sheet with codename shResult
    ' only needed for test purposes
    ' to show the result
    With shResult
        .Cells.ClearContents
        Dim i As Long
        For i = 0 To rs.Fields.Count - 1
            .Cells(1, i + 1).Value = rs.Fields(i).Name
        Next i
        .Range("A2").CopyFromRecordset rs
    End With

End Sub

Answer 2

Try this (necessary comments in code):

Sub fi()
    Dim lastRow As Long, foundRange As Range
    'this will find last row for you, don't need to hard-code it
    lastRow = Cells(Rows.Count, 1).End(xlUp).Row
    'I used nested ifs, as it will boost the performance
    'it will stop checking next conditions if preceding condition fail
    For i = 1 To lastRow
        If Cells(i, 1) = "value1" Then
        If Cells(i, 3) = "value2" Then
        If Cells(i, 4) = "value3" Then
            'add columns A through J to foundRange
            If foundRange Is Nothing Then
                Set foundRange = Range(Cells(i, 1), Cells(i, 10))
            Else
                Set foundRange = Union(foundRange, Range(Cells(i, 1), Cells(i, 10)))
            End If
        End If
        End If
        End If
    Next i
    foundRange.Select
End Sub