我使用变量的下一个循环代码的 vba 花费的时间太长

Question

New to vba and just starting loops. My for next loop code is missing something. I have large data sets to audit and part of my macro I'm using simple if then statements with true/false answers if cells match. Currently there are 43 columns and could be up to 70k rows. I am currently using the following for each of the 43 columns:

ActiveCell.FormulaR1C1 = "=IF(RC[-2]=RC[-1],TRUE,FALSE)"
ActiveCell.AutoFill Range(ActiveCell, ActiveCell.Offset(0, -7).End(xlDown).Offset(0, 7))

I wanted to simplify my code and hopefully speed up the macro with the code below. Both ways work, but this second way takes longer for some reason. I have tested and can see the values populate immediately but then I just get a wait cursor for about a minute. Can someone tell me why the application is thinking for so long after the values are in??

Dim lastrow As Long
lastrow = Range("a" & Rows.Count).End(xlUp).Row

Dim i As Long
Dim x As Integer

For i = 3 To lastrow
    For x = 5 To 134 Step 3

        For Each cell In Cells(i, x)
            If cell.Offset(0, -2).Value = cell.Offset(0, -1).Value Then
                cell.Value = True
            Else
                cell.Value = False
            End If

        Next cell
    Next x

Next i

Answer 1

One should always include the parent sheet to any Range object, this practice will help when the code begins to get more complicated.

Use Variant array when iterating. You are literally making hundreds or even thousands of trips back and forth between the sheet and vba code. Every time you do that it slows down the code a little.

With Worksheets("Sheet1")
    Dim lastrow As Long
    lastrow = .Range("a" & Rows.Count).End(xlUp).Row

    Dim rngArr As Variant
    rngArr = .Range("C3:ED" & lastrow).Value

    Dim i As Long
    For i = LBound(rngArr, 1) To UBound(rngArr, 1)
        Dim x As Long
        For x = LBound(rngArr, 2) + 2 To UBound(rngArr, 2) Step 3
            rngArr(i, x) = rngArr(i, x - 2) = rngArr(i, x - 1)
        Next x
    Next i
    .Range("C3:ED" & lastrow).Value = rngArr
End With

Answer 2

Since Scott tackled the second variation, I thought I'd offer a slight update to the first one

Sub option1()

    ActiveCell.FormulaR1C1 = "=EXACT(RC[-2],RC[-1])"
    ActiveCell.AutoFill Range(ActiveCell, Cells(ActiveCell.Offset(0, -1).End(xlDown).row, ActiveCell.Column))

End Sub

I changed the formula that you were using to the EXACT function because that's what you recreated using IF , and I also adjusted the column offsets for when you AutoFill because they seemed unusual.