无法通过 JAVA -8 64 位及更高版本的 NSIS 安装程序在 Win-10 中检查已安装的 Java 版本

Question

The installer works fine for Win-7, Win-8,but works weird for Win-10. My Java Version Check Function is -

Function checkJavaVersion
${If} ${RunningX64}
    ${registry::Read} "HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environmen" "JAVA_HOME" $0 $1
    MessageBox MB_OK "64 bit JAVA Home - $0"
    MessageBox MB_OK "64 bit JAVA Home - $1"

    ${registry::Read} "HKLM\SOFTWARE\JavaSoft\Java Runtime Environment" "CurrentVersion" $0 $1
    MessageBox MB_OK "64 bit JRE - $0"
    MessageBox MB_OK "64 bit JRE - $1"
    ${If} $0 == "" 
        ${registry::Read} "HKLM\SOFTWARE\JavaSoft\Java Development Kit" "CurrentVersion" $0 $1
        MessageBox MB_OK "64 bit JDK - $0"
        MessageBox MB_OK "64 bit JDK - $1"
    ${EndIf}

    ${registry::Read} "HKLM\SOFTWARE\WOW6432Node\JavaSoft\Java Runtime Environment" "CurrentVersion" $0 $1
    MessageBox MB_OK "32 bit JRE - $0"
    MessageBox MB_OK "32 bit JRE - $1"
    ${If} $0 == "" 
        ${registry::Read} "HKLM\SOFTWARE\WOW6432Node\JavaSoft\Java Development Kit" "CurrentVersion" $0 $1
        MessageBox MB_OK "32 bit JDK - $0"
        MessageBox MB_OK "32 bit JDK - $1"
    ${EndIf}

${Else}
    ${registry::Read} "HKLM\SOFTWARE\JavaSoft\Java Runtime Environment" "CurrentVersion" $0 $1
    MessageBox MB_OK "32 bit JRE - $0"
    MessageBox MB_OK "32 bit JRE - $1"
${EndIf}
FunctionEnd

after running this sample installer in different systems I have found out that for Win-10(64-bit system) with Java 8 (64- bit) installed it is not able to recognize the JAVA version, not even in elevated mode.

Also for Win-10(64- bit system) with JAVA 8(32-bit) installed HKLM\\SOFTWARE\\JavaSoft\\Java Runtime Environment this path redirecting the registry search to HKLM\\SOFTWARE\\WOW6432Node\\JavaSoft\\Java Runtime Environment so in both cases (32 bit & 64 bit Java Version check) Java version is found even in Elevated mode this behaves the same,

Please find the attached result for more detailed result.

This open issue NSIS installer issue can be referred for more clarity.

Answer 1

Your 64-bit detection code does not make sense, NSIS defaults to the 32-bit registry view in 32-bit installers. WOW6432Node is a reserved name and you should not really use it if possible. Elevating a installer does not change how registry redirection works.

It should probably look something like this:

${If} ${RunningX64}
  SetRegView 64
  ${registry::Read} ... $0 $1
  ...
${EndIf}
SetRegView 32
${If} $0 == "" 
  ${registry::Read} ... $0 $1
  ...
${EndIf}

According to the page you linked to, Java v9 changed the registry path and names so you need to update your code to handle those as well.

Answer 2

I resolved this issue by using:

SetRegView 64

So function which is use for checking is looking like this:

Function LocateJVM
;Check for Java version and location
Push $0
Push $1

ReadRegStr $JAVA_VER HKLM "SOFTWARE\JavaSoft\Java Runtime Environment" CurrentVersion
StrCmp "" "$JAVA_VER" Check64Bit CheckJavaVer

Check64Bit:
    SetRegView 64
    ReadRegStr $JAVA_VER HKLM "SOFTWARE\JavaSoft\Java Runtime Environment" CurrentVersion
    StrCmp "" "$JAVA_VER" JavaNotPresent CheckJavaVer

JavaNotPresent:
    StrCpy $JAVA_INSTALLATION_MSG "Java Runtime Environment nije instalirana na Vašem računaru. Da bi ste pokrenuli ovaj program potrebno je da instalirate Java 1.7 ili noviju."
    Pop $1
    Pop $0
    ;MessageBox MB_OK "Molim instalirajte Javu 1.7 ili noviju."

CheckJavaVer:
    ReadRegStr $0 HKLM "SOFTWARE\JavaSoft\Java Runtime Environment\$JAVA_VER" JavaHome
    GetFullPathName /SHORT $JAVA_HOME "$0"
    StrCpy $0 $JAVA_VER 1 0
    StrCpy $1 $JAVA_VER 1 2
    StrCpy $JAVA_VER "$0$1"
    IntCmp 17 $JAVA_VER FoundCorrectJavaVer FoundCorrectJavaVer JavaVerNotCorrect

FoundCorrectJavaVer:
    IfFileExists "$JAVA_HOME\bin\javaw.exe" 0 JavaNotPresent
    ;MessageBox MB_OK "Found Java: $JAVA_VER at $JAVA_HOME"
    Goto Done

JavaVerNotCorrect:
    ;MessageBox MB_OK "Molim instalirajte Javu 1.7 ili noviju."
    StrCpy $JAVA_INSTALLATION_MSG "Verzija Java Runtime Environment instalirana na Vašem računaru je $JAVA_VER. Da bi ste pokrenuli ovaj program potrebno je da instalirate Java 1.7 ili noviju."

Done:
    Pop $1
    Pop $0

FunctionEnd