在不同的工作簿中搜索工作表； 如果找不到匹配项，则添加工作表

Question

I have MONTHLY data by District, Territory, and Period (Period=Month) in a series of approximately 500 workbooks. There is a MASTER workbook for each District, with separate worksheets for each Territory summarizing the monthly data.

The process needed is as follows. Open each District's MASTER workbook, open each District's MONTHLY files, find the Territory worksheet in the MASTER workbook that matches the Territory identified in a cell in the MONTHLY file, paste the monthly data in the MASTER workbook's Territory worksheet, close the monthly file, then loop to the next monthly file.

I need to create a NEW Territory worksheet if a Territory is added to a District's MONTHLY files sometime after the District's MASTER workbook was initially created.

The code, it seems, is not evaluating the current MONTHLY Territory name against ALL possible MASTER workbook Territory worksheet names.
If a match is found, it should copy, paste, close the monthly file, and loop to the next MONTHLY file.
If no match is found, then it should create a new worksheet, copy, paste, close the monthly file, and loop to the next MONTHLY file.

Sub DSMReportsP02()

    Dim DistrictDSM As Range, DistrictsDSMList As Range
    Dim Period As String, Path As String, DistPeriodFile As String, Territory As String
    Dim YYYY As Variant
    Dim WBMaster As Workbook, DistMaster As Workbook, CurDstTerrFile As Workbook
    Dim wsFind As Worksheet, SheetXXX As Worksheet
    Dim wsCount As Integer, x As Integer
    Set WBMaster = ActiveWorkbook
    Period = Range("C6").Value
    YYYY = Range("C8").Value

    Set DistrictsDSMList = Range("E11:E" & Cells(Rows.Count, "E").End(xlUp).Row)

    For Each DistrictDSM In DistrictsDSMList.Cells
        Workbooks.Open Filename:="H:\Accounting\Monthend " & YYYY & "\DSM Files\DSM Master Reports\" & DistrictDSM & ".xlsx"
        Set DistMaster = ActiveWorkbook
        wsCount = Application.Sheets.Count
        Path = "H:\Accounting\Monthend " & YYYY & "\DSM Files\" & DistrictDSM & "\P02"
        DistPeriodFile = Dir(Path & "\*.xlsx")

        Do While DistPeriodFile <> ""
            Workbooks.Open Filename:=Path & "\" & DistPeriodFile, UpdateLinks:=False
            DistPeriodFile = Dir
            Set CurDstTerrFile = ActiveWorkbook
            Territory = CurDstTerrFile.Sheets("Index").Range("A3").Value

            For x = 1 To wsCount
                If DistMaster.Worksheets(x).name = Territory Then
                    CurDstTerrFile.Sheets("Index").Range("F20").Copy 'PM
                    DistMaster.Sheets(Territory).Activate
                    Range("C3").PasteSpecial Paste:=xlPasteValues
                End If

                If DistMaster.Worksheets(x).name <> Territory Then
                    CurDstTerrFile.Sheets("Index").Range("F20").Copy 'PM
                    WBMaster.Sheets("ReptTemplate").Activate
                    Range("C3").PasteSpecial Paste:=xlPasteValues
                    WBMaster.Sheets("ReptTemplate").Copy after:=DistMaster.Sheets(DistMaster.Sheets.Count)
                    DistMaster.Sheets("ReptTemplate").name = DistMaster.Sheets("ReptTemplate").Range("A1").Value
                End If
                CurDstTerrFile.Close
            Next x
        Loop
    Next DistrictDSM
End Sub

Answer 1

I believe the following will do what you expect, it may be worthwhile to note that fully qualifying your ranges is recommended specially when working with various workbooks/worksheets, so as to not confuse the code when referring to the ActiveSheet, so I would further amend the code to make sure each range is pointing to the desired workbook/worksheet:

Sub DSMReportsP02()
Dim DistrictDSM As Range, DistrictsDSMList As Range
Dim Path As String, DistPeriodFile As String, Territory As String, YYYY As String
Dim WBMaster As Workbook, DistMaster As Workbook, CurDstTerrFile As Workbook
Dim wsCount As Integer, x As Integer
Dim FoundFlag As Boolean
Set WBMaster = ThisWorkbook
Period = Range("C6").Value
YYYY = Range("C8").Value
FoundFlag = False

Application.ScreenUpdating = False
    Set DistrictsDSMList = Range("E11:E" & Cells(Rows.Count, "E").End(xlUp).Row)

    For Each DistrictDSM In DistrictsDSMList.Cells
        Set DistMaster = Workbooks.Open("H:\Accounting\Monthend " & YYYY & "\DSM Files\DSM Master Reports\" & DistrictDSM & ".xlsx")
        wsCount = DistMaster.Sheets.Count
        Path = "H:\Accounting\Monthend " & YYYY & "\DSM Files\" & DistrictDSM & "\P02"
        DistPeriodFile = Dir(Path & "\*.xlsx")

        Do While DistPeriodFile <> ""
            Set CurDstTerrFile = Workbooks.Open(Path & "\" & DistPeriodFile)
            DistPeriodFile = Dir
            Territory = CurDstTerrFile.Sheets("Index").Range("A3").Value

            For x = 1 To wsCount
                If DistMaster.Worksheets(x).Name = Territory Then
                    FoundFlag = True 'set flag to found if worksheet found
                    DistMaster.Sheets(Territory).Range("C3").Value = CurDstTerrFile.Sheets("Index").Range("F20").Value 'PM
                End If
            Next x
            If FoundFlag = False Then 'if worksheet not found then add it
                WBMaster.Sheets("ReptTemplate").Range("C3").Value = CurDstTerrFile.Sheets("Index").Range("F20").Value 'PM
                WBMaster.Sheets("ReptTemplate").Copy After:=DistMaster.Sheets(DistMaster.Sheets.Count)
                DistMaster.Sheets("ReptTemplate").Name = DistMaster.Sheets("ReptTemplate").Range("A1").Value
            End If
            CurDstTerrFile.Close
            FoundFlag = False 'reset the flag before next iteration of the loop
        Loop
    Next DistrictDSM
Application.ScreenUpdating = True
End Sub