sed匹配包含特殊字符的多行，并替换匹配模式的一部分

Question

Consider the following set of lines as a text file:

START This is a 
sample paragraph that has special characters like new lines

spaces, tabs, quotes "abc", equals =, angular brackets <abc>, front slash / and might contain the starting string that should be ignored
START and 

END

START

dfgfah

END

Using sed, I want to replace text between only the first occurrence of START and the first occurrence of END .

The result that I am expecting is like:

START new_text END

START

dfgfah

END

What I tried is like:

sed ':a;N;$!ba;s/START.*END/START New text END/' sample.txt>sample_2.txt

But the result was:

START New text End

How do I replace until the first occurrence of END ?

Answer 1

With GNU sed:

sed '0,/START/{:a;/END/!{N;ba};s/.*/START new_text END/;}' file

• 0,/START/ : from first occurrence of START
• :a;/END/!{N;ba} : append new lines to the pattern space until END is found
• when above loops ends, replace merged lines with START new_text END

Answer 2

You can use : do define labels and b to branch to the label in sed scripts.

The option -n tells sed to print no lines automatically. Instead you can print the lines with the p command.

In the following example the :head loop loops over the part up to the first START and the :tail loop loops over the text after the first END . The :start loop loops over the part between the first START and END .

The :head and :tail loops print ( p ) every line ( n ) and quit, when they reach the end of the file ( $q ). The :start loop does not print and just ignores the content. When the END is found, the new text gets inserted ( s ) and printed ( p ).

cat <<EOF |
START This is a 
sample paragraph that has special characters like new lines

spaces, tabs, quotes "abc", equals =, angular brackets <abc>, front slash / and might contain the starting string that should be ignored
START and 

END

START

dfgfah

END
EOF
sed -n '
:head
/^START/{
  :start
  n
  $q
  /^END/{
    s/^/START New text /
    p
    n
    :tail
    p
    $q
    n
    b tail
  }
  b start
}
p
$q
n
b head
'

The above technique is taken from the first example of The Geek Stuff's sed tutorial .