Excel VBA函数隐藏/取消隐藏行

Question

I am new to VBA/Macro. I need some help figuring how to hide/unhide rows given my scenario. This is my table:

See Table: enter image description here

What I would like to do is:

1) Create a function (or sub) with three arguments:

• FlagRange: flagRange or C1:C9
• hideAction: True/False
• Flag: This is one of the flag value

Example: Hide_Unhide(flagRange, True, "P")

2) This function will hide all the row(s) based on the Flag that is passed into the argument.

Any suggestions and samples are appreciated.

Answer 1

Here are two options. The second sub is going to be faster as it will hide all the rows at once rather many possible iterations of hiding rows. The larger the # of rows to be hidden, the more you will notice the time saved by using the Union approach

Option Explicit

Sub HideMe(FlagRange As Range, Flag As String)

FlagRange.EntireRow.Hidden = False
Dim FlagCell As Range

Application.ScreenUpdating = False
    For Each FlagCell In FlagRange
        FlagCell.EntireRow.Hidden = FlagCell = Flag 'Rows get hidden here
    Next FlagCell
Application.ScreenUpdating = True

End Sub

---

Option Explicit

Sub HideMeUnion(FlagRange As Range, Flag As String)

FlagRange.EntireRow.Hidden = False
Dim FlagCell As Range, HideMe As Range

For Each FlagCell In FlagRange
    If FlagCell = Flag Then
        If HideMe Is Nothing Then
            Set HideMe = FlagCell
        Else
            Set HideMe = Union(HideMe, FlagCell)
        End If
    End If
Next FlagCell

'rows gettin hidden here all at once
If Not HideMe Is Nothing Then HideMe.EntireRow.Hidden = True

End Sub

Answer 2

Try this:

Private sub Hide_Unhide(FlagRange as Range, Hide as Boolean, FlagValue as String)
Dim c as Variant
    For Each c in FlagRange
           c.EntireRow.Hidden = False
    Next c
    For Each c in FlagRange
        If c.Value2 = FlagValue Then
           c.EntireRow.Hidden = Hide
        End IF
    Next c
End Sub

Answer 3

You can use the following solution to to hide/unhide rows:

Function Hide_Unhide(flagRange As Range, hideAction As Boolean, Flag As String)
        For Each Row In flagRange.Rows
            If Row.Cells(3) = Flag Then
                Row.EntireRow.Hidden = hideAction
            End If
        Next Row
End Function