如何根据多个单元格值自动隐藏和取消隐藏excel中的行

Question

enter image description here I'm a newbie to excel macro. I'm trying to create a macro to automatically hide and unhide rows in excel based on multiple cell value. I have created two drop down cells with value using data validation and based on the drop down I'm trying to hide and unhide. If the first drop down is "Class I" and second drop down value is Ä only row from 8 to 20 should be visible and row from 21 to end of the rows to be hidden and similarly when the first drop down is "Class I" and second drop down value is "B" row from 8 to end of rows should be hidden except for rows from 23 to 31. If require I can provide the excel file it contains dummy data

Answer 1

Put this code in the worksheet's private code sheet accessed though right-click worksheet name tab, View Code. Modify the row ranges to suit.

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)

    If Not Intersect(Target, Range("D3, D4")) Is Nothing Then
        On Error GoTo meh
        Application.ScreenUpdating = False
        Range("8:" & Me.UsedRange.Rows.Count).EntireRow.Hidden = True
        Select Case Range("D3").Value2
            Case "Class I"
                Select Case Range("D4").Value2
                    Case ChrW(196)  'Ä
                        Intersect(Range("8:20"), Me.UsedRange).EntireRow.Hidden = False
                    Case "B"
                        Intersect(Range("21:33"), Me.UsedRange).EntireRow.Hidden = False
                    Case Else
                        'do nothing
                End Select
            Case "Class II"
                'copy above for Class I here
                'modify rows to show/hide
            Case Else
                'do nothing
        End Select
    End If

meh:
    Application.ScreenUpdating = True

End Sub