Excel VBA-从合并顶部单元格的列中获取顶部单元格

Question

I have a macro where I am going through columns and identifying whether the "top" cell (row 7, because there are various irrelevant headers) matches certain specified values, and then performing various actions.

The problem is that some of the headers are merged cells. This means that the code correctly recognises only columns which align with the left-most column which the header cell straddles. Clearly, I need to change this to resolve this.

I don't know how to get this to record a value for, eg, column D and Column E, where a merged cell in both column D and E says "manager" or "director".

For the moment, I've just included a made-up action ("y = 22") because I'm trying to get the basic principle right before progressing.

Sub LabourCalc()

    Dim x As Variant
    Dim y As Variant

    Workbooks("XXX").Activate
    Sheets("XXX").Activate

    For x = 1 To 10
        If InStr(Cells(7, x).Value, "MANAGER") _
        Or InStr(Cells(7, x).Value, "manager") _
        Or InStr(Cells(7, x).Value, "Manager") _
        Or InStr(Cells(7, x).Value, "DIRECTOR") _
        Or InStr(Cells(7, x).Value, "Director") _
        Or InStr(Cells(7, x).Value, "director") Then
            y = 22
        End If
    Next x

End Sub

Answer 1

Use the Range.MergeArea property.

Returns a Range object that represents the merged range containing the specified cell. If the specified cell isn't in a merged range, this property returns the specified cell.

So for example, if D7:E7 is a merged cell:

• Cells(7, 4).MergeArea.Cells(1, 1) refers to D7
• Cells(7, 5).MergeArea.Cells(1, 1) also refers to D7 . Cell E7 is empty.

And if F7 is not a merged cell:

• Cells(7, 6).MergeArea.Cells(1, 1) refers to F7 .

As pointed out by @ValonMiller in the comments, you can simplify the multiple InStr instances by first converting the contents of Cells(7, x) to uppercase using UCase .

Your final loop then could look like:

With Workbooks("XXX").Sheets("XXX")
    For x = 1 To 10
        With .Cells(7, x).MergeArea.Cells(1, 1)
            If InStr(UCase(.Value), "MANAGER") Or InStr(UCase(.Value), "DIRECTOR") Then
                ' Do your stuff here
            End If
        End With
    Next x
End With

Answer 2

All those comments and no one provided an actual working answer. Try this:

Sub LabourCalc()

    Dim wb as Workbook
    Set wb = Workbooks("XXX")

    Dim ws as Worksheet
    Set ws = wb.Worksheets("XXX")

    For x = 1 To 10
        Select Case UCase$(ws.Cells(7,x).MergeArea.Cells(1,1))
            Case is = "MANAGER","DIRECTOR"
                'do stuff here
        End Select
    Next

End Sub

If you need to check if the Manager or Director appear within the cell do this:

Dim checkValue as String
checkValue = UCase$(ws.Cells(7,x).MergeArea.Cells(1,1))

Select Case Instr(checkValue,"MANAGER") > 0 Or Instr(checkValue,"DIRECTOR") > 0
    Case is = True
        'do stuff
End Select