使用VBA将选定的行移到excel表的顶部或底部（不包括一列）

Question

I want to have two VBA codes the first one moves the selected cell row in column (A, C, D, E and F) to the Top and other one moves the row cells to the bottom of the excel table.

For example if I select the cell in the C3 and run the macro the cells (A3, C3, D3,E3 and F3) in a row will move to the bottom of the table.

I have the following code which moves the entire row to the bottom:

Public Sub MoveToBottom()

    If Selection.Row <> 1 Then

        'move the whole row
        Selection.EntireRow.Cut
        Range("B1").End(xlDown).Offset(1, 0).EntireRow.Insert

    End If

End Sub

My Data looks like

Thanks in advance

Answer 1

This is pretty quick and dirty but should do the trick for you.

It first checks that the selected row: has values, is not the header, and is not already the top/bottom row (depending on the function).

Then it inserts a row (for top only), copies the current row to where it belongs, and deletes the "old" row.

Option Explicit

Sub MoveToTop()

    Dim rowCurrent As Long
    rowCurrent = Selection.row

    If WorksheetFunction.CountA(rows(rowCurrent)) >= 5 _
    And rowCurrent <> 1 And rowCurrent <> 2 Then
        Range("A2, C2:F2").Insert Shift:=xlDown

        Range("A" & rowCurrent).copy Destination:=Range("A2")
        Range("C" & rowCurrent & ":F" & rowCurrent).copy Destination:=Range("C2:F2")

        Range("A" & rowCurrent & ", " & "C" & rowCurrent & ":F" & rowCurrent).Delete
    End If

End Sub


Sub MoveToBottom()

    Dim rowCurrent As Long
    rowCurrent = Selection.row

    Dim rowLast As Long
    rowLast = Range("A" & rows.count).End(xlUp).row

    If WorksheetFunction.CountA(rows(rowCurrent)) >= 5 _
    And rowCurrent <> 1 And rowCurrent <> rowLast Then
        Range("A" & rowCurrent).copy Destination:=Range("A" & rowLast + 1)
        Range("C" & rowCurrent & ":F" & rowCurrent).copy Destination:=Range("C" & rowLast + 1 & ":F" & rowLast + 1)

        Range("A" & rowCurrent & ", " & "C" & rowCurrent & ":F" & rowCurrent).Delete
    End If

End Sub