如何使用VBA在Excel中仅按顺序编号可见行？

Question

The goal is to have my code number only the visible rows in sequence so that if a filter is applied or lines are deleted the end user can click the "Refresh" button, shown in the image below, updating the sequence and the summary at the top of the page.

The code I am using at the moment applies to all the cells in the range including those that are hidden and I have no idea how to change it so that it only applies to the visible cells.

This is the Report

And this is the code attached to my "Refresh" button;

Private Sub Refresh_Click()

Application.Goto Reference:="R10C2"
Selection.End(xlDown).Select

Dim maxRowIndex As Long
Dim rowCounter As Long

maxRowIndex = ActiveCell.Row - 9
rowCounter = 1

Range("A10").Select

For rowCounter = 1 To maxRowIndex
ActiveCell = rowCounter
ActiveCell.Offset(1).Select
Next

End Sub

Thanks in advance!

Answer 1

This is untested, so try it out on a copy of your data, I also assumed you want to put the numbering in column A :

Private Sub Refresh_Click()

Dim totalRows As Long
Dim rowCounter As Long
Dim i as long

rowCounter = 1
totalRows = ActiveSheet.UsedRange.Rows.Count + ActiveSheet.UsedRange.Row - 1    

for i = 10 to totalRows
    If ActiveSheet.Rows(i).Hidden = False then 
        Range("A" & i).Value = rowCounter 
        rowCounter = rowCounter + 1
    End if  
Next i

End Sub

This will basically loop through all the rows, check to see if they're visible and if yes, insert the row counter

Answer 2

Work through the cells in the SpecialCells(xlCellTypeVisible).

Option Explicit

Private Sub Refresh_Click()

    Dim a As Long, n As Long, r As Range

    If CBool(Application.Subtotal(103, Range(Cells(10, "B"), Cells(Rows.Count, "B")))) Then
        Range(Cells(10, "B"), Cells(Rows.Count, "B").End(xlUp)).Offset(0, -1).ClearContents
        For Each r In Range(Cells(10, "B"), Cells(Rows.Count, "B").End(xlUp)).SpecialCells(xlCellTypeVisible)
            n = n + 1
            r.Offset(0, -1) = n
        Next r
    End If

End Sub

Answer 3

You don't need the VBA to number only the visible rows. The WorkSheetFunction SUBTOTAL will give you the same result.

 =SUBTOTAL(3,B$10:B10)