使用没有日期/时间格式的 Excel VBA 检查时间

Question

I'm trying to ensure that the user of the tool only inserts valid time values. This input need to be numeric and not in datetime format. I understand that conditional formatting from the front-end would be a lot simpler, but a copy-paste action will overwrite the conditional formatting. So I've decided to write in a macro for it with the following logic : 1) Input has to be in number format '0000' 2) The first 2 digits have to be lesser than 23 AND 3) The last 2 digits have to be lesser than 59

This is the code I have so far but it's not giving me the intended output. Where is the error or is there a more effective way of solving this?

Worksheets("SheetA").Range("A2:A" & lastRow).NumberFormat = "0000"

For count = 2 To (lastRow + 1)
If IsEmpty(Worksheets("SheetA").Range("A" & count).Value) = True Then
    Worksheets("SheetA").Range("A" & count).Interior.Color = RGB(255, 255, 204)
Else
    If (Left(Worksheets("SheetA").Range("A" & count).Text, 2)) > 23 Or (Right(Worksheets("SheetA").Range("A" & count).Text, 2)) > 59 Then
        Worksheets("SheetA").Range("A" & count).Interior.Color = RGB(255, 0, 0)
    End If
End If
Next count 

Answer 1

In a normal module create a procedure to format your number as text and test it's within the required range:

Public Sub TestNumber(Target As Range)

    Dim FormattedNumber As String

    'Return formatted "text" version of value.
    FormattedNumber = Format(Target, "0000")

    'Assume the value is correct and set the cell to "valid" colour.
    Target.Interior.Color = RGB(255, 255, 204)

    'Validate the value - check it's length, that it's a number
    'and falls with the specified ranges.
    If Len(FormattedNumber) = 4 And IsNumeric(Val(FormattedNumber)) Then
        If Val(Left(FormattedNumber, 2)) < 0 Or Val(Left(FormattedNumber, 2)) > 23 Or _
         Val(Right(FormattedNumber, 2)) < 0 Or Val(Right(FormattedNumber, 2)) > 59 Then
            Target.Interior.Color = RGB(255, 0, 0)
        Else
            'Remove if you don't want to reformat the number.
            Target.Value = Format(FormattedNumber, "00:00")
        End If
    Else
        Target.Interior.Color = RGB(255, 0, 0)
    End If

End Sub

On each sheet you want to check numbers in column 1 add this code:

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim rCell As Range

    If Not Intersect(Target, Columns(1)) Is Nothing Then
        Application.EnableEvents = False
            For Each rCell In Target
                TestNumber rCell
            Next rCell
        Application.EnableEvents = True
    End If

End Sub

The Application.EnableEvents lines are only required if you reformat the entered number at the end of the TestNumber procedure. Not adding the command fires the Change event a second time with the reformatted number - which will return incorrect results, before firing again and eventually returning 00:00 .

Edit:
Have updated the Change event so it will work if more than one cell is changed (if a range of numbers are pasted in) and changed an AND to an OR in the TestNumber procedure (it was accepting 6000 previously).

Edit again:
If you want to check the number as entered remove the FormattedNumber variable and replace with Target and format the column as text so you don't lose the leading 0.

Answer 2

LEFT Function (Worksheet / VBA)

The Excel LEFT function can be used both as a worksheet function and a VBA function. The LEFT function returns the specified number of characters in a text string, starting from the first or left-most character. Use this function to extract a sub-string from the left part of a text string. Syntax: LEFT(text_string, char_numbers). It is necessary to mention the text_string argument which is the text string from which you want to extract the specified number of characters. The char_numbers argument is optional (when using as a worksheet function), which specifies the number of characters to extract from the text string. The char_numbers value should be equal to or greater than zero; if it is greater than the length of the text string, the LEFT function will return the text string in full; if omitted, it will default to 1. While using as a VBA function, it is necessary to specify both the arguments, and if text_string contains Null, the function also returns Null.

If you want obtain your goal i have an alternative for you: your input have to be a string after your control you convert the string in number if is a time else no conversation.

to convert string in number example:

Dim finalNumber As Integer
    If IsNumeric(myVar) Then
        finalNumber = CInt(myVar)
    Else
        finalNumber = 0
    End If

and limit input with this step https://www.extendoffice.com/documents/excel/952-excel-cell-character-limit.html