如果可执行文件不存在，如何安装 32 位或 64 位可执行文件？

Question

I've tried two variations of scripts to install an executable file after checking for the correct processor type. I believe the executable runs, but for some reason its failing to check if the file already exists. I will post both here.

Can some one please help?

@echo on
if /i "%processor_architecture%"=="x86" (
    if exist "C:\Program Files\Credential Wizard\CredentialWizard.exe" (
        echo ***App is Installed Successfully***
    ) else (\\srvfs01.flymyrtlebeach.com\deployment$\Software\Nervepoint\nam-creds-provider-windows-x86-2.0.4.exe -q)
) else if /i "%processor_architecture%"=="X64" (
    if exist "C:\Program Files (x86)\Credential Wizard\CredentialWizard.exe" (
        echo ***App is Installed Successfully***
    ) else (\\srvfs01.flymyrtlebeach.com\deployment$\Software\Nervepoint\nam-creds-provider-windows-x64-2.0.4.exe -q)
)
exit

Or this one

@echo off

Set RegQry=HKLM\Hardware\Description\System\CentralProcessor\0
REG.exe Query %RegQry%  | Find /i "x86" 
If %ERRORLEVEL% == 0 (
    GOTO X86
) ELSE (
    GOTO X64
)

:X86
IF NOT EXIST "C:\Program Files\Credential Wizard\CredentialWizard.exe"(start \\srvfs01.flymyrtlebeach.com\deployment$\Software\Nervepoint\nam-creds-provider-windows-x86-2.0.4.exe -q)
GOTO END

:X64
IF NOT EXIST "C:\Program Files (x86)\Credential Wizard\CredentialWizard.exe"(start \\srvfs01.flymyrtlebeach.com\deployment$\Software\Nervepoint\nam-creds-provider-windows-x64-2.0.4.exe -q)
:End
exit

Answer 1

I suggest to read the Microsoft documentation pages

• WOW64 Implementation Details
• File System Redirector
• Registry Keys Affected by WOW64

A batch file can be executed on 64-bit Windows by cmd.exe in directory

• %SystemRoot%\\System32 (x64) or
• %SystemRoot%\\SysWOW64 (x86)

Which cmd.exe is used depends on the architecture of the application calling the batch file. A 32-bit installer executable running a batch file results in getting the batch file interpreted by 32-bit Windows command processor and so the batch file runs in 32-bit environment like on 32-bit Windows even on being executed on 64-bit Windows.

For that reason a batch file used to install either a 32- or a 64-bit application needs to always find out first in which environment it is executed by which operating system.

Further it does not matter which architecture the CPU of the PC has. It can be an x64 processor, but installed is nevertheless 32-bit Windows. In this case it is not possible to use 64-bit applications, although the CPU would support them because of installed Windows does not support them.

There are some other facts which must be taken into account:

1. Are there registry keys created during the installation which are affected by WOW64?
   In this case it would be better on batch file being currently executed in 32-bit environment on 64-bit Windows to be started again in 64-bit environment before doing the install.

2. Is the batch file executed by an installer application which continues immediately on cmd.exe finished executing the batch file?
   In this case it is necessary that the batch file execution by 32-bit cmd.exe is halted until 64-bit cmd.exe finished execution of the batch file in 64-bit environment on 64-bit Windows and then exits without doing anything in 32-bit environment.

I suggest to use this batch file for your task:

@echo off
rem Is the batch file executed by 32-bit cmd.exe on 32-bit Windows?
if "%ProgramFiles(x86)%" == "" goto DoInstall

rem Is the batch file executed by 64-bit cmd.exe on 64-bit Windows?
if not exist "%SystemRoot%\Sysnative\cmd.exe" goto DoInstall

rem Run this batch file by 64-bit instead of 32-bit cmd.exe on 64-bit Windows.
rem This simple method works only if batch file is executed without arguments.
"%SystemRoot%\Sysnative\cmd.exe" /C "%~f0"

rem Exit batch file executed by 32-bit cmd.exe on 64-bit Windows
rem after 64-bit cmd.exe finished execution of the batch file.
goto EndBatch

:DoInstall
rem echo Processor architecture:  %PROCESSOR_ARCHITECTURE%
rem echo Program files directory: %ProgramFiles%
rem echo Common program files:    %CommonProgramFiles%

if exist "%ProgramFiles%\Credential Wizard\CredentialWizard.exe" goto Installed
if not "%ProgramFiles(x86)%" == "" if exist "%ProgramFiles(x86)%\Credential Wizard\CredentialWizard.exe" goto Installed

rem When \\srvfs01.flymyrtlebeach.com\deployment$\Software\Nervepoint\
rem contains always just one installer executable for 32-bit and one for
rem for 64-bit, let the batch file use that one independent on its version
rem number in file name.
for %%I in ("\\srvfs01.flymyrtlebeach.com\deployment$\Software\Nervepoint\nam-creds-provider-windows-%PROCESSOR_ARCHITECTURE%-*.exe") do (
    copy /V "%%I" "%TEMP%\%%~nxI"
    "%TEMP%\%%~nxI" -q
    del "%TEMP%\%%~nxI"
    goto ReCheck
)

:ReCheck
if exist "%ProgramFiles%\Credential Wizard\CredentialWizard.exe" goto Installed
if not "%ProgramFiles(x86)%" == "" if exist "%ProgramFiles(x86)%\Credential Wizard\CredentialWizard.exe" goto Installed

echo === ERROR: App installation failed. ===
echo/
pause
goto EndBatch

:Installed
echo *** App is installed successfully. ***

:EndBatch

Note: I added a FOR loop to run either nam-creds-provider-windows-x86-2.0.4.exe or nam-creds-provider-windows-x64-2.0.4.exe or any other nam-creds-provider-windows-x*-*.exe in case of version 2.0.4 of the executable is ever replaced by a newer version.

The batch file works even with disabled command extensions.

For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.

• cmd /?
• echo /?
• exit /?
• for /?
• goto /?
• if /?
• pause /?
• rem /?

PS: Run %SystemRoot%\\System32\\cmd.exe for example with a double click on this file and run set pro . Let the 64-bit command prompt window open and run next from Windows Explorer %SystemRoot%\\SysWOW64\\cmd.exe also with a double click on this file and run set pro in 32-bit command prompt window. Compare the output environment variables in both command prompt windows.