如何在Delphi 7中使用DELETE方法和JSON流源发送Indy请求？

Question

I have a problem in sending web service request using Delphi 7 and Indy. My workplace a public hospital as a client and insurance third party as the server. Here is the service catalogue:

URL : {BASE URL from the insurance office}/Delete
    Method : DELETE
    Format : Json
    Content-Type: Application/x-www-form-urlencoded
    Request body : 
        {"request": {"t_obj": {"noObj": "0301X1018V001","user": "myUser"}}}

I use Indy 10.6 and some of the code I wrote is:

  Json := '{"request": {"t_obj": {"noObj": "0301X1018V001","user": "myUser"}}}'; req := TStringStream.Create(Utf8Encode(Json)); resp := TStringStream.Create(''); IdHttp1.request.Source := req; IdHttp1.Request.ContentType := 'Application/x-www-form-urlencoded'; IdHttp1.delete('{BASE URL from the insurance office}/Delete', resp); showmessage(resp.DataString); 

But, when the request sent, it failed to delete. Any one can help me, please? I'm sorry my English is not good enough. Thank you.

Answer 1

Application/x-www-form-urlencoded is not a valid media type for sending JSON. Are you sure the server is not actually expecting application/json instead? It should be.

Beside that, a more important reason why your request does not work is because the TIdHTTP.Delete() method simply does not allow sending a post body, so the server never sees the JSON at all. Internally, Delete() calls the TIdCustomHTTP.DoRequest() method passing nil in the ASource parameter, which replaces your assignment of the TIdHTTP.Request.Source property.

To do what you are attempting, you will have to call DoRequest() directly, eg:

// TIdCustomHTTP.DoRequest() is protected,
// so use an accessor class to reach it...
type
  TIdHTTPAccess = class(TIdHTTP)
  end;

...

Json := '{"request": {"t_obj": {"noObj": "0301X1018V001","user": "myUser"}}}';
req := TStringStream.Create(UTF8Encode(Json));
try
  resp := TStringStream.Create('');
  try
    //IdHttp1.Request.Source := req;
    //IdHttp1.Request.ContentType := 'Application/x-www-form-urlencoded';
    IdHttp1.Request.ContentType := 'application/json';
    //IdHttp1.Delete('{BASE URL from the insurance office}/Delete', resp);
    TIdHTTPAccess(IdHttp1).DoRequest(Id_HTTPMethodDelete, '{BASE URL from the insurance office}/Delete', req, resp, []);
    ShowMessage(resp.DataString);
  finally
    resp.Free;
  end;
finally
  req.Free;
end;