如何使用Spock框架编写多个单元测试？

Question

The goal of this test is to take an integer array, find the max value, and count the frequency of that max value. How would I change this code to test multiple times. Also, I'd like to know if this is the correct approach to testing this problem.

I'm new to TDD and I'm currently practicing writing tests for easily solvable practice problems.

Thanks!

import spock.lang.Specification

class BirthdayCandlesTest extends Specification {
    def "GetNumberOfMaxHeightCandles"() {
        given: "A BirthdayCandles object"
        int[] test = [1,1,1,3,3,3,3]
        def candles = new BirthdayCandles(test)

        when: "I call the max number height method"
        def result = candles.getNumberOfMaxHeightCandles()

        then: "I should get the frequency count of the max number in the integer array"
        result == 4
    }
}

Answer 1

You can add a where: block with a table of values with the first row being the variable names which can be used in the rest of the test. For example

def "GetNumberOfMaxHeightCandles"() {
        given: "A BirthdayCandles object"
        def candles = new BirthdayCandles("$test")

        when: "I call the max number height method"
        def result = candles.getNumberOfMaxHeightCandles()

        then: "I should get the frequency count of the max number in the integer array"
        result == "$result"

        where:
        test             |     result
        [1,1,1,3,3,3,3]  |     4
        [1,1,1,3,3,3,4]  |     1
}

and just add rows to add test variations.

Answer 2

As John Camerin stated you're probably looking for Data Driven Testing in spock.

I'll provide a slightly different answer:

def "GetNumberOfMaxHeightCandles"() {
    given: "A BirthdayCandles object"
    def candles = new BirthdayCandles(testInput)

    when: "I call the max number height method"
    def actual = candles.getNumberOfMaxHeightCandles()

    then: "I should get the frequency count of the max number in the integer array"
    actual == expectedResult

    where:
    testInput                  |     expectedResult
    [1,1,1,3,3,3,3]  as int [] |     4
    [1,1,1,3,3,3,4]  as int [] |     1
}

A couple of observations:

• Note that I didn't use string interpolation here (no "$result" and "$test")

• Note the as int[] in the where block. An alternative to it would be def candles = new BirthdayCandles(testInput as int [])