在excel vba中返回绝对值的行和列

Question

my question is why doesn't it like the AddressOfMaxRow & AddressOfMaxCol variables? Am I being an idiot?

Function MaxABS(rng, AddressOfMaxRow, AddressOfMaxCol, MaxVal)

Dim arr As Variant

arr = rng.Value

For i = 1 To UBound(arr, 1)

    For j = 1 To UBound(arr, 2)
        arr(i, j) = VBA.Abs(arr(i, j))
    Next
Next

MaxVal = Application.WorksheetFunction.Max(arr)


AddressOfMaxRow = WorksheetFunction.Index(arr, WorksheetFunction.Match(WorksheetFunction.Max(arr), arr, 0)).Cells.Row

AddressOfMaxCol = WorksheetFunction.Index(arr, WorksheetFunction.Match(WorksheetFunction.Max(arr), arr, 0)).Cells.Column

End Function

Answer 1

Perhaps something like this, which returns the address (eg $D$9 ) of the "max" cell, but can be tweaked to return the row and column as needed.

Note that this assumes that rng only contains numeric values and can be beefed up to not error if there's text, for example. It will also only return the first max value address if the max value appears more than once.

Function MaxABS(rng As Range) As String
    Dim arr As Variant
    arr = rng.Value

    Dim i As Long, j As Long
    Dim tempMax As Double
    Dim tempRow As Long, tempCol As Long

    For i = 1 To UBound(arr, 1)
        For j = 1 To UBound(arr, 2)
            arr(i, j) = VBA.Abs(arr(i, j))
            If arr(i, j) > tempMax Then
                tempMax = arr(i, j)
                tempRow = i
                tempCol = j
            End If
        Next j
    Next i

    MaxABS = rng.Cells(tempRow, tempCol).Address
End Function

To return the row and column (separated by a comma since the desired output format was not specified), replace the last line

MaxABS = rng.Cells(tempRow, tempCol).Address

with the following:

With rng.Cells(tempRow, tempCol)
    MaxABS = .Row & "," & .Column
End With

with sample output of 9, 4 instead of $D$9 .