Excel VBA 尝试为数组编写函数时出现 #Value 错误

Question

I am trying to find the shortest string in an array from a worksheet. However, when I try to execute the function I get a #Value error. What am I doing wrong? Thanks!

Function ShortestString(ByVal array1 As Range)

Dim nRows As Integer
Dim i As Integer
Dim cell As String
Dim cellLength As Integer
Dim string1 As String

nRows = array1.Rows.Count
cellLength = 100
cell = array1.Cells(i, 1).Value

For i = 1 To nRows
    If cellLength > Len(cell) Then
    cellLength = Len(cell)
    string1 = cell
    End If
Next i

ShortestString = string1

End Function

Answer 1

Several issues in your code.

• First, you never assign i before you call cell = array1.Cells(i, 1).Value . That's going to be a run-time error 1004.
• Second, you should test the input Range to make sure it's an "array" before you do anything else. If it's a single cell, you can skip everything else and just return the text of that cell.
• Third, you never update the value of cell anywhere in your function - it will always be the uninitialized value of vbNullString .
• Fourth, the maximum cell text length is 32767 characters, not 100. You should use that as your initial value.

My guess is that you're looking for something more like this:

Option Explicit

Public Function ShortestString(ByVal target As Range) As String
    Dim rowCount As Long, columnCount As Long
    rowCount = target.Rows.Count
    columnCount = target.Columns.Count

    If rowCount = 1 And columnCount = 1 Then
        ShortestString = target.Text
        Exit Function
    End If

    Dim rowIdx As Long, colIdx As Long
    Dim shortest As String, current As String
    shortest = String(32767, " ")

    For rowIdx = 1 To rowCount
        For colIdx = 1 To columnCount
            current = target.Cells(rowIdx, colIdx).Text
            If Len(current) <= Len(shortest) Then
                shortest = current
            End If
        Next
    Next

    ShortestString = shortest
End Function

Note that you can probably actually use an array instead of testing individual cells, but that's an optimization you can make if the performance isn't up to snuff.

---

Edit:

You can convert the function to use an array of cell values by reading the entire range into a Variant() :

Dim cellValues() As Variant
cellValues = target.Value

For rowIdx = 1 To rowCount
    For colIdx = 1 To columnCount
        current = CStr(cellValues(rowIdx, colIdx))
        If Len(current) <= Len(shortest) Then
            shortest = current
        End If
    Next
Next