vb.net上的FormatException是未处理的错误

Question

I'm new to Stack Overflow, but anyway I'm having problem regarding my code. When I try to run the program and click the Login function I am getting an error on this statement ... Adapter.Fill(Table) It says: FormatException was unhandled. An unhandled exception of type 'System.FormatException' occurred in mscorlib.dll Additional information: Input string was not in a correct format.

Imports MySql.Data.MySqlClient
Public Class Login_page
    Private Sub Login_page_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Me.CenterToScreen()
    End Sub

    Private Sub PictureBox3_Click(sender As Object, e As EventArgs) Handles PictureBox3.Click
        Close()
    End Sub

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim MysqlConnection As New MySqlConnection("host=127.0.0.1; user=root; database = storage_db")
        Dim Command As New MySqlCommand("SELECT * FROM `login_access` where username = @username and password = @password", MysqlConnection)

        Command.Parameters.AddWithValue("@username", SqlDbType.VarChar).Value = TextBoxUsername.Text
        Command.Parameters.AddWithValue("@password", SqlDbType.VarChar).Value = TextBoxPassword.Text

        Dim Adapter As New MySqlDataAdapter(Command)
        Dim Table As New DataTable()

        Adapter.Fill(Table)

        If Table.Rows.Count() <= 0 Then
            MessageBox.Show("Invalid")
        Else
            MessageBox.Show("Login Successfully")
        End If

    End Sub
End Class

Answer 1

These lines are wrong for a number of reasons:

Command.Parameters.AddWithValue("@username", SqlDbType.VarChar).Value = TextBoxUsername.Text
Command.Parameters.AddWithValue("@password", SqlDbType.VarChar).Value = TextBoxPassword.Text

Firstly, you're using MySqlClient for MySQL, not SqlClient for SQL Server. That means that you need to use MySqlDbType and not SqlDbType .

Secondly and thirdly, you need to decide whether you're using Add or AddWithValue because, as it is, you're mixing and matching. If you use AddWithValue then you don't specify the data type as it is inferred from the value:

Command.Parameters.AddWithValue("@username", TextBoxUsername.Text)
Command.Parameters.AddWithValue("@password", TextBoxPassword.Text)

That's generally discouraged though, because the inferred type is often not the type you want. That means that you should use Add . In that case, you should also specify the size of variable-length data types:

Command.Parameters.Add("@username", MySqlDbType.VarChar, 50).Value = TextBoxUsername.Text
Command.Parameters.Add("@password", MySqlDbType.VarChar, 50).Value = TextBoxPassword.Text

EDIT:

For the record, what was happening in your original code was basically this:

Dim p = Command.Parameters.AddWithValue("@username", SqlDbType.VarChar)

p.Value = TextBoxUsername.Text

So a parameter was being added with a value of SqlDbType.VarChar , which would have been interpreted as an Integer and the parameter data type inferred from that. The Value of that parameter was then being set using a String that could not be converted to an Integer , thus the FormatException was thrown.