使用jq从JSON文件中提取信息，并将信息设置在变量中

Question

I want to extract an information from a JSON file called blablabla.json which look like this:

{
  "token": {
   "issued_at": "2018-11-04T23:35:07Z",
   "expires_at": "2018-11-05T00:35:07Z",
   "user": {
    "id": "ide",
    "name": "ide"
   }
  }
}

I want to get the "expires_at" date to compare it with the current date. To do that, I use this:

type blablabla.json|jq .token".expires_at"

It works, but I don't know how to set it to a variable. I try somethings like:

SET date=type blablabla.json|jq .token".expires_at"

but it does nothing. Do you have an idea?

Thank you very much.

Answer 1

Generally, you'd use a For /F loop:

@Echo Off
For /F "Delims=" %%A In ('type blablabla.json^|jq .token".expires_at"'
) Do Set "Expiry=%%~A"

Where your result can be accessed using the variable, %Expiry% . (You wouldn't set a variable to the name of an important existing system variable) .

As for checking it against the current date, you'd need to find a method of doing that as both dates would be strings, not date objects. That is outside of the scope of this question .

Answer 2

I'd use PowerShell for this (at least as a tool) for several reasons:

1. it has direct support for json
2. it has a [datetime] type to do calculations

This one line PowerShell script returns expires.at as a day diffference from today including conversion from UTC.

(([datetime](Get-Content .\blablabla.json |ConvertFrom-Json).token.expires_at).Date - (Get-Date).date).Days

And can easily be wrapped in a batch.

@Echo off
For /f %%A in ('
powershell -NoP -C "(([datetime](Get-Content .\blablabla.json |ConvertFrom-Json).token.expires_at).Date - (Get-Date).date).Days"
') Do Set "Expires=%%A"
Set Expires

This will (for today) return:

Expires=0

and negative values for past dates, positive values for future dates.

Answer 3

Yes, I know that a .json file should not be processed via a Batch file for a large number of reasons. However, if the problem is simple (like this one) and there are not additional constraints, then a Batch file solution could be the simplest one, like this two-lines code that includes the date comparison...

for /F "tokens=2 delims=, " %%a in ('findstr "expires_at" blablabla.json') do set "expires=%%~a"
if %expires:~0,4%%expires:~5,2%%expires:~8,2% geq %date:~6,4%%date:~0,2%%date:~3,2% goto expired

Answer 4

With Xidel it's as simple as:

xidel -s blablabla.json -e "$json//expires_at"

This returns its value: 2018-11-05T00:35:07Z .

To export this as %expdate% :

FOR /F "delims=" %%A IN ('xidel.exe -s blablabla.json -e "expdate:=$json//expires_at" --output-format=cmd') DO %%A

Xidel can also return the current date in the same format:

xidel -s blablabla.json -e "$json//expires_at,current-dateTime()"

This returns:

2018-11-05T00:35:07Z
2019-01-07T18:26:33.453