如何向 NSIS 安装程序添加新页面

Question

My requirement is, I need to add a new page (for eg., "newpage") after the "Directory" page. For this first i need to change the pushbutton (Install) to (Next) in the Directory page so that I can create a new page by clicking on "Next".

For this I verified the "Directory" page in the path (NSIS/Contrib/Modern UI 2/Pages)

I didn't find "

Later i verified the "Interface" page and found "Next", "Cancel", and "Back" buttons. But didn't find the "Install" button.

Where can i find the "Install" button?

And also how to create a new page? Can we create a new NSI file for the "newpage" and include it in the main .nsi file?

If i create a new NSI file, do i need to create strings for all the required languages in different files for localization?

And also If i create different language files, can i place those in the local directory folder?

Answer 1

NSIS automatically changes the Next/Install button text for you. Only the page before the InstFiles page uses the "Install" string as the button text.

You must use a plug-in to create a custom page. The most commonly used page plug-in is nsDialogs and it's part of the default NSIS install.

You don't have to put the custom page nor the translation strings in separate .nsh files, you can put the code directly in your .nsi:

Unicode True
Page Components
Page Directory
Page Custom MyPageCreate
Page InstFiles

LoadLanguageFile "${NSISDIR}\Contrib\Language Files\English.nlf"
LangString MyLabelText ${LANG_ENGLISH} "Hello World"
LoadLanguageFile "${NSISDIR}\Contrib\Language Files\Swedish.nlf"
LangString MyLabelText ${LANG_SWEDISH} "Hej bork bork"

!include nsDialogs.nsh

Function MyPageCreate
nsDialogs::Create 1018
Pop $0

${NSD_CreateLabel} 0 0 100% 12u "$(MyLabelText)"
Pop $0

nsDialogs::Show
FunctionEnd

If you want to put translations in separate files then you should take a look at \\NSIS\\Include\\LangFile.nsh , it contains a example that uses MUI and helper macros to create additional translation strings in external files.