使用xsl：param在xsl：template中选择属性

Question

I need to output 2 attributes of a kind of element. I'd like to use only 1 template with one parameter to reduce code.

XML is like :

<myElement attribute1="x" attribute2="y" />

I'd like to call templates like this :

<xsl:apply-templates select="myElement">
   <xsl:with-param name="paramAttr" select="@attribute1" />
</xsl:apply-templates>

and

<xsl:apply-templates select="myElement">
  <xsl:with-param name="paramAttr" select="@attribute2" />
</xsl:apply-templates>

Problem is in the definition of the template :

<xsl:template match="myElement">
  <xsl:param name="paramAttr"/>

  <xsl:value-of select="$paramAttr" /> <!-- NOT ACCEPTED -->

</xsl:template>

I tried different things like introducing @ at different places, with concat() or {} without much success. Any idea ? thank you.

Answer 1

Pass the attribute name as a string:

<xsl:apply-templates select="myElement">
   <xsl:with-param name="paramAttr" select="'attribute1'" />
</xsl:apply-templates>

and select the attribute based on its name in the called template:

<xsl:template match="myElement">
  <xsl:param name="paramAttr"/>
  <xsl:value-of select="@*[name() = $paramAttr]" />
</xsl:template>

Answer 2

You haven't really explained what problem occurred with your current approach but I think it results from the rule on how xsl:with-param is evaluated, if you look at https://www.w3.org/TR/xslt-10/#element-with-param it says

The current node and current node list used for computing the value specified by xsl:with-param element is the same as that used for the xsl:apply-templates or xsl:call-template element within which it occurs

respectively XSLT 3 defines in https://www.w3.org/TR/xslt-30/#element-with-param that

The focus used for computing the value specified by the xsl:with-param element is the same as that used for its parent instruction.

That means, if the outer context/focus of your xsl:apply-templates has a myElement child you select for the apply-templates , in the xsl:with-param you need to use <xsl:with-param name="paramAttr" select="myElement/@attribute1 "/>, as the xsl:apply-templates doesn't change the context/focus for its inner xsl:with-param . Of course using a variable with eg

 <xsl:variable name="el" select="myElement"/>
 <xsl:apply-templates select="$el">
    <xsl:with-param name="paramAttr" select="$el/@attribute1"/>
 </xsl:apply-templates>

can make that approach shorter and more readable. If there are several myElement elements then it is better to change the context/focus either with

<xsl:for-each select="myElement">
  <xsl:apply-templates select=".">
    <xsl:with-param name="paramAttr" select="@attribute1"/>
  </xsl:apply-templates>
</xsl:for-each>

or to first push the myElement element to a template where you then further process the attributes.