具有实现接口的通用类型参数的不同类型的拆箱实例

Question

I am working on an abstraction for a variation on a key-value store style API where I have the following interfaces (simplified for clarity).

type IValue =
    abstract member Id: int64

type IKey<'value when 'value :> IValue> = interface end

type IKeyGenerator<'value, 'key when 'value :> IValue and 'key :> IKey<'value>> =
    abstract member Generate: 'value -> 'key

type IKeyValueStore<'value when 'value :> IValue> =
    abstract member Store: 'value -> unit
    abstract member Get: int64 -> 'value option
    abstract member Find<'key when 'key :> IKey<'value>> : 'key -> 'value option   

Basically, each value can be looked up by multiple keys, and the keys for each value are generated by IKeyGenerator s. When I call Store on the IKeyValueStore , I want to find all the key generators for the given value, run each of them, and store each key for the value so it can then be retrieved by any of those keys.

My problem is that, while I can reflectively discover all implementations of IKeyGenerator that have a 'value type parameter that matches the 'value type for this IKeyValueStore , I can't safely unbox them to a consistent type. I tried unboxing them all to IKeyGenerator<'value, IKey<'value>> , but this doesn't work if the concrete implementations don't explicitly implement the interface that way. If they implement the interface referring to a specific implementation of IKey , the unboxing fails.

I then tried introducing a simplified IKeyGenerator<'value> interface that defined the Generate method as simply returning IKey<'value> instead of 'key :> IKey<'value> , which solves the problem with unboxing all the implementations, but I then run into problems downstream with not knowing the actual type of the key (for example, in order to do the Find when there are multiple possible keys for this value).

Is there some way I can safely obtain a list of IKeyGenerator instances for different IKey implementations, provided that they all implement IKey<'value> for the same type of value?

Answer 1

I would recommend a two-tier implementation of the key generators: a base class that implements IKeyGenerator , but itself has more concrete type parameters, constrained in the way you have there:

type IKeyGenerator<'value when 'value :> IValue> =
    abstract member Generate: 'value -> IKey<'value>

[<AbstractClass>]
type KeyGeneratorBase<'value, 'key when 'value :> IValue and 'key :> IKey<'value>> =
    abstract member Generate: 'value -> 'key

    interface IKeyGenerator<'value> with
        override this.Generate v = this.Generate v :> _

Then have specific implementations inherit from KeyGeneratorBase .

This way, the implementations can have their concrete types to work with, and the consumer will have the narrow types that it expects.

Or, alternatively (and I much prefer this way), have a function to create IKeyGenerator s:

let mkKeyGenerator<'value, 'key when 'value :> IValue and 'key :> IKey<'value>> (gen : 'value -> 'key) = 
    { new IKeyGenerator<_> with 
        member this.Generate v = gen v :> _
    }

---

PS I know this is not what you asked for, but I must warn against excessive use of reflection and classes. This never ends well. Consider a more functional, idiomatic approach.