案例声明未评估我对MS Access VBA的期望

Question

I am trying to figure out why my case statement is not executing as I believe it should. In the below sub, rs1.recordcount evaluates to 0, and the other 4 evaluate to 1. To be sure of this I have printed the results of each recordset.recordcount both before the case statement is executed and also after it has executed. However when I step through the code, I get the complete opposite of what I expect. When I step through it, the second case statement Case rs2.RecordCount = 0 is executed despite the fact that the statement evaluates to equal 1. Any help would be much appreciated. Thank you!

Option Compare Database

Sub CheckDataTypes()

    Set db = CurrentDb
    Set rs1 = db.OpenRecordset("SELECT [Dual Year Carrier Report].EE_ID FROM [Dual Year Carrier Report] WHERE ((([Dual Year Carrier Report].EE_ID) Is Not Null));")
    Set rs2 = db.OpenRecordset("SELECT [Dual Year Carrier Report].PERSON_OID FROM [Dual Year Carrier Report] WHERE ((([Dual Year Carrier Report].PERSON_OID) Is Not Null));")
    Set rs3 = db.OpenRecordset("SELECT [Dual Year Carrier Report].SPONSOR_OID FROM [Dual Year Carrier Report] WHERE ((([Dual Year Carrier Report].SPONSOR_OID) Is Not Null));")
    Set rs4 = db.OpenRecordset("SELECT [Dual Year Carrier Report].ZIP_CD FROM [Dual Year Carrier Report] WHERE ((([Dual Year Carrier Report].ZIP_CD) Is Not Null));")
    Set rs5 = db.OpenRecordset("SELECT [Dual Year Carrier Report].EP_PERSON_OID FROM [Dual Year Carrier Report] WHERE ((([Dual Year Carrier Report].EP_PERSON_OID) Is Not Null));")

Debug.Print rs1.RecordCount & ", " & rs2.RecordCount & ", " & rs3.RecordCount & ", " & rs4.RecordCount & ", " & rs5.RecordCount



Select Case intRecordCount

Case rs1.RecordCount = 0
    Debug.Print rs1.RecordCount
    MsgBox ("Please import Dual Year Carrier Report again and make sure to change the proper fields to text data type")

Case rs2.RecordCount = 0
    MsgBox ("Please import Dual Year Carrier Report again and make sure to change the proper fields to text data type")

Case rs3.RecordCount = 0
    MsgBox ("Please import Dual Year Carrier Report again and make sure to change the proper fields to text data type")

Case rs4.RecordCount = 0
    MsgBox ("Please import Dual Year Carrier Report again and make sure to change the proper fields to text data type")

Case rs5.RecordCount = 0
    MsgBox ("Please import Dual Year Carrier Report again and make sure to change the proper fields to text data type")

End Select
    Debug.Print rs1.RecordCount & ", " & rs2.RecordCount & ", " & rs3.RecordCount & ", " & rs4.RecordCount & ", " & rs5.RecordCount

End Sub

Answer 1

Note that your intRecordCount variable is never assigned a value.

Each Case should be followed by a value against which intRecordCount can be compared. In your code example's Case rs1.RecordCount = 0 , the rs1.RecordCount = 0 first evaluates to a Boolean that will be True if there are no records in rs1; comparing intRecordCount and a Boolean doesn't make sense.

You could simplify your code as follows:

If (rs1.RecordCount = 0) Or (rs2.RecordCount = 0) Or (rs3.RecordCount = 0) Or (rs4.RecordCount = 0) Or (rs5.RecordCount = 0) Then
    MsgBox "Please import Dual Year Carrier Report again and make sure to change the proper fields to text data type"
End If

Answer 2

1) use Option Explicit

2) declare variables

3) vba Case statement doesn't work like that. Your statement looks a little bit like SQL Server syntax and a lot wrong.

4) trick for young players: if you want to know how many records in your recordset then you need to access all the records.

5) [not shown] consider rewriting your SQL statements as "select count(*) as recCount from [Dual Year Carrier Report] where ..." and checking the value of rs1("recCount") , rs2("recCount"), etc.

Option Compare Database
Option Explicit

Sub CheckDataTypes()

    Dim db As DAO.Database
    Dim rs1 As DAO.Recordset, rs2 As DAO.Recordset, rs3 As DAO.Recordset, rs4 As DAO.Recordset, rs5 As DAO.Recordset

    Set db = CurrentDb

    Set rs1 = db.OpenRecordset("SELECT [Dual Year Carrier Report].EE_ID FROM [Dual Year Carrier Report] WHERE ((([Dual Year Carrier Report].EE_ID) Is Not Null));")
    If Not rs1.EOF Then rs1.MoveLast    ' required to force MS Access to load records to recordset NOW
    Set rs2 = db.OpenRecordset("SELECT [Dual Year Carrier Report].PERSON_OID FROM [Dual Year Carrier Report] WHERE ((([Dual Year Carrier Report].PERSON_OID) Is Not Null));")
    If Not rs2.EOF Then rs2.MoveLast
    Set rs3 = db.OpenRecordset("SELECT [Dual Year Carrier Report].SPONSOR_OID FROM [Dual Year Carrier Report] WHERE ((([Dual Year Carrier Report].SPONSOR_OID) Is Not Null));")
    If Not rs3.EOF Then rs3.MoveLast
    Set rs4 = db.OpenRecordset("SELECT [Dual Year Carrier Report].ZIP_CD FROM [Dual Year Carrier Report] WHERE ((([Dual Year Carrier Report].ZIP_CD) Is Not Null));")
    If Not rs4.EOF Then rs4.MoveLast
    Set rs5 = db.OpenRecordset("SELECT [Dual Year Carrier Report].EP_PERSON_OID FROM [Dual Year Carrier Report] WHERE ((([Dual Year Carrier Report].EP_PERSON_OID) Is Not Null));")
    If Not rs5.EOF Then rs5.MoveLast

    Debug.Print rs1.RecordCount & ", " & rs2.RecordCount & ", " & rs3.RecordCount & ", " & rs4.RecordCount & ", " & rs5.RecordCount

    If rs1.RecordCount = 0 Then
        Debug.Print rs1.RecordCount
        MsgBox ("Please import Dual Year Carrier Report again and make sure to change the proper fields to text data type")
    ElseIf rs2.RecordCount = 0 Then
        MsgBox ("Please import Dual Year Carrier Report again and make sure to change the proper fields to text data type")
    ElseIf rs3.RecordCount = 0 Then
        MsgBox ("Please import Dual Year Carrier Report again and make sure to change the proper fields to text data type")
    ElseIf rs4.RecordCount = 0 Then
        MsgBox ("Please import Dual Year Carrier Report again and make sure to change the proper fields to text data type")
    ElseIf rs5.RecordCount = 0 Then
        MsgBox ("Please import Dual Year Carrier Report again and make sure to change the proper fields to text data type")
    End If

    Debug.Print rs1.RecordCount & ", " & rs2.RecordCount & ", " & rs3.RecordCount & ", " & rs4.RecordCount & ", " & rs5.RecordCount

End Sub

Hope this helps, GraemeR