Excel VBA-下标超出范围

Question

I need help. The below code is written to add to column data and store in another column. When I execute the code it says subscript out of range in for loop where it adds to array values.

Kindly give an advice.

Thanks

Sub test()

    Dim W1, W2, R1, R2, R3, R4, R5 As Double
    Dim i, j, T As Integer
    Dim myRange As Double
    Dim Arr1 As Variant, Arr2 As Variant, Arr3 As Variant

    myRange1 = Worksheets("Sheet2").Range("M15", "M30")
    myRange2 = Worksheets("Sheet2").Range("N15", "N30")
    R1 = WorksheetFunction.Sum(myRange1)
    R2 = WorksheetFunction.Sum(myRange2)
    R3 = (R1 + R2)
    R4 = (R1 / R3) * 100
    R5 = (R2 / R3) * 100
    Range("M31") = R4
    Range("N31") = R5
    Arr1 = Range("M15:M30").Value
    Arr2 = Range("N15:N30").Value

    For i = LBound(Arr1) To UBound(Arr1)
        Arr3(i) = Arr1(i) + Arr2(i)
    Next

    T = 16
    For j = 1 To T
        Range("M" & 33 + j).Cells = Arr3
    Next

End Sub

Answer 1

Arr3 is never The error is caused because Arr3 was never initialized as an array. Arr1(i) will also throw an error because Arr1 is a 2 dimensional array; use Arr1(i, 1) instead.

ReDim Arr3(LBound(Arr1) To UBound(Arr1))
For i = LBound(Arr1) To UBound(Arr1)
    Arr3(i) = Arr1(i, 1) + Arr2(i, 1)
Next

 Dim W1, W2, R1, R2, R3, R4, R5 As Double 

In the declaration above R5 's datatype is Double the rest are Variants.

Here are a few videos that will help: Excel VBA Introduction Part 3 - What to do When Things Go Wrong (Errors and Debugging) , Excel VBA Introduction Part 34 - Type Declarations (User-Defined Types) and Excel VBA Introduction Part 25 - Arrays

Answer 2

1. Use explicit sheet name for Range references
2. You create a 2D array when reading a range into an array so use Transpose if planning on looping as shown as will generate a 1D array off the single column ranges being passed in
3. Declare and Redim Arr3 so enough space for all items

Code:

Option Explicit
Public Sub TEST()
    Dim Arr1(), Arr2(), Arr3(), i As Long, ws As Worksheet
    Set ws = ThisWorkbook.Worksheets("Sheet1")

    Arr1 = Application.Transpose(ws.Range("M15:M30").Value)
    Arr2 = Application.Transpose(ws.Range("N15:N30").Value)
    ReDim Arr3(1 To UBound(Arr1))
    For i = LBound(Arr1) To UBound(Arr1)
        Arr3(i) = Arr1(i) + Arr2(i)
    Next
End Sub

Answer 3

you could use a 2D array

Public Sub TEST()    
    Dim Arr(), Arr3(), i As Long
    With ThisWorkbook.Worksheets("Sheet1").Range("M15:N30") ' reference wanted range in wanted sheet and workbook
            Arr = .Value ' store referenced range values in an array
            ReDim Arr3(1 To UBound(Arr, 1))
            For i = 1 To UBound(Arr, 1)
                Arr3(i) = Arr(i, 1) + Arr(i, 2)
            Next
        .Offset(18).Resize(, 1).Value = Application.Transpose(Arr3) ' paste array values to referenced range offsetted 18 rows down and resize to one column
    End With
End Sub