在安装软件时，如果特定条件为假，如何使用NSIS回退软件安装过程？

Question

My requirement is when installing the software using NSIS installer, it should call the function and check if the UPS is connected to the computer or not.

If the UPS is connect it would complete the installation process.

If the UPS battery is not connected it would show a message box asking "Please connect the UPS and try again with "Cancel" and "Retry" buttons". If "cancel" is clicked, it would Roll back the installation process.

I am able to get if the UPS is connected or not using the below line of code:

 System::Call "$INSTDIR\drvutil.dll::IsUPSPresent() i.r0 ?e"

Then I am using the "If" condition and checking if the UPS is connected or not

 ${If} $0 = 0

If the condition is false, I need to show the Messagebox like "Please connect the UPS and try again with "Cancel" and "Retry" buttons". If I click on "Cancle", It should Roll back the installation process. And If i connect the UPS (or the condition is True) then installation should complete.

Please help me how to implement this logic.

Below is my code snippet:

; The stuff to install
Section "UPSTest (required)"

  SectionIn RO

  DetailPrint "Testing UPS"

  SetOutPath $INSTDIR

  ; Give the dll path
  File E:\TestNullSoft\ValidateUPS.exe
  File E:\TestNullSoft\drvutil.dll
  File E:\TestNullSoft\UpsControl.dll
  File E:\TestNullSoft\UpsDevice.dll
  File E:\TestNullSoft\pdcdll.dll

  System::Call 'KERNEL32::AddDllDirectory(w "$INSTDIR")' ; Tell Windows we trust all .DLLs in this directory

  System::Call "$INSTDIR\drvutil.dll::IsUPSPresent() i.r0 ?e"
  Pop $1
  MessageBox MB_OK "Return value = $0, lasterr = $1"
  ; In the below line If the return value is 0("false"), That means UPS is not connected to the computer
   ${If} $0 = 0
   ; Here I need to show the Messagebox like "Please connect the UPS and try again with "Cancel" and "Retry" buttons"
   ; If I click on "Cancle", It should Roll back the installation process.

  ; Write the installation path into the registry
  WriteRegStr HKLM SOFTWARE\NSIS_UPSTest "Install_Dir" "$INSTDIR"

  ; Write the uninstall keys for Windows
  WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\UPSTest" "DisplayName" "NSIS UPSTest"
  WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\UPSTest" "UninstallString" '"$INSTDIR\uninstall.exe"'
  WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\UPSTest" "NoModify" 1
  WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\UPSTest" "NoRepair" 1
  WriteUninstaller "uninstall.exe"

SectionEnd

Please provide your inputs on this.

Answer 1

Instead of trying to roll back a partial install you can just put the .DLL in a temporary directory and do the check there just before you start installing files:

!include LogicLib.nsh

Section
InitPluginsDir
SetOutPath $PluginsDir
File "something\mydll.dll"
SetOutPath $Temp ; Don't hold the lock on $PluginsDir
System::Call 'KERNEL32::AddDllDirectory(w "$PluginsDir")' 

retry:
System::Call '$PluginsDir\mydll.dll::IsUPSPresentDummyFunction(i 0 r0)i.r0?e' ; Fake a return FALSE system call for this example
Pop $1 ; LastError
${If} $0 = 0
    MessageBox MB_RETRYCANCEL|MB_ICONEXCLAMATION "Blah blah UPS blah blah error $1" IDRETRY retry
    Abort "UPS required!" ; You can replace this with Quit if you want
${EndIf}

SetOutPath $InstDir
WriteUninstaller "$InstDir\uninstall.exe"
File "something\myapp.exe"
...
SectionEnd

$PluginsDir is deleted automatically when the installer exits.