遍历过滤器中的枢轴项时，vba SpecialCells（xlCellTypeVisible）无法正常工作

Question

I am using the below code to cycle through items in a filter in a pivot table and then copy the filtered results.

But for some reason the code fails to account for the items that have no results and instead appears to copy the previous results instead.

I have error handling in the code for the items that will show no results but it just doesn't seem to work - when walking through the code it skips the 'if' I have placed in there to catch the 'nothing'.

It then (when it gets to the copying/pasting part of the code) copies the (now hidden) cells that were visible under the last item selected in the filter on the previous loop.

I have missed off the end of the code as it gets a bit lengthy and it all works, it's just the bit with the visible cells I can't seem to get working.

Sub Bulletin_Chase()

Dim pt As PivotTable
Dim pi As PivotItem
Set pt = Worksheets("By User").PivotTables("PivotTable1")

Dim rng As Range
Dim OutApp As Object
Dim OutMail As Object
Dim strbody As String

For Each pi In pt.PageFields("Supplier").PivotItems
  pt.PageFields("Supplier").CurrentPage = pi.Name

With Range("Filters")
    .AutoFilter Field:=2, Criteria1:=Array("false"), Operator:=xlFilterValues
End With

On Error Resume Next
Set rng = Worksheets("By User").Range("Bulletin_List").SpecialCells(xlCellTypeVisible)

If rng Is Nothing Then
    Worksheets("By User").AutoFilterMode = False
    Range("Filters").AutoFilter
    GoTo Continue
End If

etc...

Really struggling with this so any help at all from you geniuses would be greatly appreciated.

Answer 1

When trying to set rng, if there are no visible cells, then the assignment fails and it skips to the next line of code. This process does not set rng to Nothing. It just does nothing, which leaves rng with the value it had from the last time the loop ran.

The simplest solution is to force rng to be nothing just before trying to assign it to visible cells. That way, if the assignment fails, you will successfully detect the failure when you test for rng = nothing:

Range("Filters").AutoFilter Field:=2, Criteria1:=Array("false"), Operator:=xlFilterValues 'No need for a With block if you're only performing 1 method

set rng = Nothing 'Clear the rng variable before trying to assign a new range to it
On Error Resume Next
Set rng = Worksheets("By User").Range("Bulletin_List").SpecialCells(xlCellTypeVisible)
On Error Goto 0 'Restore normal On Error behaviour to trap any other unexpected errors