Google表格IMPORTXML查询

Question

I'm using Google Sheets as web scraper.

I have been using this IMPORTXML

=importxml(A1, "//div[@class='review-content']//text()")

and this is the results

Row1: {"publishedDate":"2019-01-05T22:19:28Z","updatedDate":"null","reportedDate":"null}

Row2: {"publishedDate":"2018-12-10T22:19:28Z","updatedDate":"null","reportedDate":"null}

Row3: {"publishedDate":"2018-12-09T22:19:28Z","updatedDate":"null","reportedDate":"null}

but am having trouble figuring out how to get only the "publishedDate" value. Example:

Row1: 2019-01-05T22:19:28Z

Row2: 2018-12-10T22:19:28Z

Row3: 2018-12-09T22:19:28Z

Any ideas as to what I may be missing

Answer 1

How about these 3 samples? I thought them from the samples of your question. I think that there are several answers for your situation. So please think of this as 3 samples of them.

It supposes that the URL is put in the cell "A1".

Sample 1:

=ARRAYFORMULA(MID(IMPORTXML(A1, "//div[@class='review-content']//text()"),19,20))

• When the length of string of each value is the constant, how about this?
  • The value is retrieved by MID() .

Sample 2:

=ARRAYFORMULA(INDEX(SPLIT(IMPORTXML(A1, "//div[@class='review-content']//text()"),"""",TRUE,TRUE),,4))

• When the position of each value is the constant, how about this?
  • The value is retrieved by SPLIT() and INDEX() .

Sample 3:

=ARRAYFORMULA(REGEXEXTRACT(IMPORTXML(A1, "//div[@class='review-content']//text()"),"publishedDate"":""(\w.+?)"""))

• When the pattern of each value is the constant, how about this?
  • The value is retrieved by REGEXEXTRACT() .

References:

• MID
• SPLIT
• INDEX
• REGEXEXTRACT

If these were not the results you want, I apologize. At that time, in order to correctly replicate your situation, can you provide the URL you are using as @Rubén says?