VBA #Value错误在Excel 2010中但不在Excel 2016中

Question

So I wrote the following code on my pc at home (with Excel 2016 installed) where it works without any problems, but now that i try to use it at my work Excel gives my an #Value error. I tried searching up differences between Excel 2016 and 2010, but failed to find anything regarding my issue.

Public Function comparex(a, b As Long) As Byte
Dim a1, a2, b1, b2, e, e1 As Long
Dim y As Integer
y = 1
a1 = a - 1000
a2 = a + 1000
b1 = b - 1000
b2 = b + 1000
Do Until Sheets(2).Cells(y, 3) = ""
    e = Sheets(2).Cells(y, 3).Value
    e1 = Sheets(2).Cells(y, 4).Value
    If a1 < e And a2 > e And b1 < e1 And b2 > e1 Then
        comparex = 1
        Exit Do
    Else
        y = y + 1

    End If

Loop
End Function

Basically the script is supposed to check if there are values near a and b in a column on another sheet.

Answer 1

This procedure should work for you. Rather than a Byte it returns a boolean, meaning either True or False, which would be more usual than a Byte.

Public Function CompareX(a As Long, b As Long) As Boolean

    Dim a1 As Long, a2 As Long
    Dim b1 As Long, b2 As Long
    Dim e As Long, e1 As Long
    Dim R As Long, Rl As Long

    y = 1
    a1 = a - 1000
    a2 = a + 1000
    b1 = b - 1000
    b2 = b + 1000

    With Sheets(2)
        Rl = .Cells(.Rows.Count, 3).End(xlUp).Row
        For R = 1 To Rl
            e = .Cells(R, 3).Value
            e1 = .Cells(R, 4).Value
            If a1 < e And a2 > e And b1 < e1 And b2 > e1 Then
                CompareX = True
                Exit For
            End If
        Next R
    End With
End Function

Although the above is more mainstream. it doesn't seem very useful if this case. Apparently you are attempting to find a row in which all criteria are met. The reasonable result to expect would be the row number where this was the case. For such a purpose the function would be constructed slightly different, as shown below.

Public Function CompareX(a As Long, b As Long) As Long

    Dim a1 As Long, a2 As Long
    Dim b1 As Long, b2 As Long
    Dim e As Long, e1 As Long
    Dim R As Long, Rl As Long

    y = 1
    a1 = a - 1000
    a2 = a + 1000
    b1 = b - 1000
    b2 = b + 1000

    With Sheets(2)
        Rl = .Cells(.Rows.Count, 3).End(xlUp).Row
        For R = Rl To 1 Step -1
            e = .Cells(R, 3).Value
            e1 = .Cells(R, 4).Value
            If a1 < e And a2 > e And b1 < e1 And b2 > e1 Then
                CompareX = R
                Exit For
            End If
        Next R
    End With
End Function

As you see, the function counts the row backward. If no match was found it will return zero, meaning, so long as it returns a number a match was found. However, in case there are more matches than one, the row number will be that of the last match in the list.