'，`和|和有什么区别？何时使用？

Question

I've seen strings written like in these three ways:

lv_str  = 'test'
lv_str2 = `test`
lv_str3 = |test|

The only thing I've notice so far is that ' trims whitespaces sometimes, while ` preserves them.
I just recently found | - don't know much about it yet.

Can someone explain, or post a good link here when which of these ways is used best and if there are even more ways?

Answer 1

|...| denotes ABAP string templates. With string templates we can create a character string using texts, embedded expressions and control characters.

• ABAP Docu
• Examples

Answer 2

Use ' to define character-typed literals and non-integer numbers:

CONSTANTS some_chars TYPE char30 VALUE 'ABC'.
CONSTANTS some_number TYPE fltp VALUE '0.78'.

Use ` to define string-typed literals:

CONSTANTS some_constant TYPE string VALUE `ABC`.

Use | to assemble text:

DATA(message) = |Received HTTP code { status_code } with message { text }|.

This is an exhaustive list of the ways ABAP lets you define character sequences.

Answer 3

To answer the "when should they be used" part of the question:

` and | are useful if trailing spaces are needed (they are ignored with ' , cf this blog post for more information, be careful SCN renders today the quotes badly so the post is confusing) :

DATA(arrival) = `Hello ` && `world`.
DATA(departure) = |Good | && |bye|.

Use string templates ( | ) rather than the combination of ` and && for an easier reading (it remains very subjective, I tend to prefer | ; with my keyboard, | is easier to obtain too) :

DATA(arrival) = `Dear ` && mother_name && `, thank you!`. 
DATA(departure) = |Bye { mother_name }, thank you!|.

Sometimes you don't have the choice: if a String data object is expected at a given position then you must use ` or | . There are many other cases.

In all other cases, I prefer to use ' (probably because I obtain it even more easily with my keyboard than | ).

Answer 4

Although the other answers are helpful they do not mention the most important difference between ' and ` .

A character chain defined with a single quote will be defined as type C with exactly the length of the chain even white spaces at the beginning and the end of the character sequence.

So this one 'TEST' will get exactly the type C LENGTH 4 .

wherever such a construct `TEST` will evaluate always to type string .

This is very important for example in such a case.

REPORT zutest3.

DATA i TYPE i VALUE 2.
DATA(l_test1) = COND #( WHEN i = 1 THEN 'ACT3' ELSE 'ACTA4').
DATA(l_test2) = COND #( WHEN i = 1 THEN `ACT3` ELSE `ACTA4`).

WRITE l_test1.
WRITE l_test2.