如何在两个工作表之间进行交叉引用，并在第三工作表上按发生次数对总和/组进行交叉引用？

Question

I'm extremely new to excel worksheets and need some help figuring this issue out. The first sheet Cookbook lists the departments and their respective recipes. There's a many-to-many relationship between the departments and products.

I have another sheet Ingredients that lists the Ingedients and what Recipes they belong to:

I want to get the total of each category by ingredient in a third sheet titled Category x Ingredient Totals :

The X in the Ingredients table represents 1 implicitly, but I'm not sure how to convert that (among other things).

Answer 1

This will work for you but there may be someone out there that can do it better. I like my code to be quite verbose but strip it down as you need.

With the first table, create a range over the data (not including the header) called " rngCategoriesToRecipes "

Next, create a range over the second table (this time including the headers) called " rngRecipetoIngredients ".

Thirdly, add the following code into a new module within the VBA editor ...

Public Function CalculateCategoryToIngredients( _
        ByVal rngCategoriesToRecipesMapping As Range, _
        ByVal rngRecipesToIngredientsMapping As Range, _
        ByVal strCategory As String, _
        ByVal strIngredient As String) As Long

    Application.Volatile

    Dim strThisCategory As String, strThisRecipe As String, strThisIngredient As String, strRecipes As String, objCell As Range
    Dim lngRow As Long, lngCol As Long, arrRecipes, bIsRelevant As Boolean, strThisValue As String, lngCount As Long

    ' Process each of the different categories and they're mappings to recipes.
    For i = 1 To rngCategoriesToRecipesMapping.Rows.Count
        strThisCategory = rngCategoriesToRecipesMapping.Cells(i, 1)
        strThisRecipe = rngCategoriesToRecipesMapping.Cells(i, 2)

        ' Get all of the recipes related to the category passed in.
        If strThisCategory = strCategory Then
            strRecipes = strRecipes + "," + strThisRecipe
        End If
    Next

    arrRecipes = Split(Mid(strRecipes, 2), ",")

    ' Now process the mapping from the recipes to the ingredients.
    For lngRow = 2 To rngRecipesToIngredientsMapping.Rows.Count
        For lngCol = 2 To rngRecipesToIngredientsMapping.Columns.Count
            strThisValue = Trim(rngRecipesToIngredientsMapping.Cells(lngRow, lngCol))
            strThisRecipe = rngRecipesToIngredientsMapping.Cells(lngRow, 1)
            strThisIngredient = rngRecipesToIngredientsMapping.Cells(1, lngCol)

            bIsRelevant = False

            For i = 0 To UBound(arrRecipes)
                If arrRecipes(i) = strThisRecipe Then
                    bIsRelevant = True
                    Exit For
                End If
            Next

            If bIsRelevant And strThisValue <> "" And strIngredient = strThisIngredient Then
                lngCount = lngCount + 1
            End If
        Next
    Next

    CalculateCategoryToIngredients = lngCount
End Function

Finally, add this formula in the first cell within the range that you want to calculate and fill down and across.

=CalculateCategoryToIngredients(rngCategoriesToRecipes,rngRecipetoIngredients,$A16,B$15)

Naturally, you'll need to replace the last 2 parameters ($A16 = "Category 1" and B$15 = "Ingredient 1") with the actual cells you need to reference, they're currently relative to my worksheet and where I placed my values.

I hope it works for you. I think it did, it highlighted that your matrix intersection "Category 3", "Ingredient 3" is actually 2, not 1 ... as you illustrated.