向DCG添加解析约束

Question

Graphic tokens can serve as Prolog operators that don't require single quotes.

A translation of ISO/IEC 13211-1:1995, 6.4.2 "Syntax.Tokens.Names" is:

graphic_token --> kleene_plus(graphic_token_char).

graphic_token_char --> member("#$&*+-./:<=>?@^~\\").

% some auxiliary code
kleene_plus(NT) --> NT, kleene_star(NT).

kleene_star(NT) --> "" | kleene_plus(NT).

member(Xs) --> [X], { member(X,Xs) }.

Subsection 6.4.1 "Syntax.Tokens.Layout Text" adds the following constraint:

A graphic token shall not begin with the character sequence comment open (ie, " /* ").

Enforcing that restriction in the DCG is no big deal...

graphic_token --> graphic_token_char.    % 1  char
graphic_token -->                        % 2+ chars
   
   { dif([C1,C2], "/*") },
   kleene_star(graphic_token_char).

... but quite ugly! How do I make it pretty again (and keep it bidirectional)?

Answer 1

I'm not sure this is prettier, but maybe something like this:

graphic_token --> kleene_plus_member("#$&*+-.:<=>?@^~\\",0'/).
graphic_token --> "/", kleene_star_member("#$&+-./:<=>?@^~\\", 0'*).

kleene_plus_member(Xs, Code) --> member(Xs), kleene_star(member([Code|Xs])).

kleene_star_member(Xs, Code) --> "" | member(Xs), kleene_star(member([Code|Xs])).

The first clause of graphic_token parses a graphic token that does not begin with / and the second clause the one which starts with it.