在Batch FOR / F命令中使用空格

Question

I'm writing a batch file in Windows to test if some processes are running and have found the following script works as expected.

set EXE=uTorrent.exe

FOR /F %%x IN ('tasklist /NH /FI "IMAGENAME eq %EXE%"') DO IF %%x == %EXE% echo uTorrent is running...

but the following fails...

set EXE=Plex Media Server.exe

FOR /F %%x IN ('tasklist /NH /FI "IMAGENAME eq %EXE%"') DO IF %%x == %EXE% echo Plex is running...

I am pretty sure this is because there are spaces in the second process name?

Could you please explain the changes needed to fix this problem?

Answer 1

When using for /f and not specifying tokens= , the default is 1 token. And with a default delimiter of space, that means it's matching just the first word of your multi word search criteria.

I tried fixing the example by adding "tokens=*" and wrapping the later comparison with double-quotes, but that just ended up capturing the full output from tasklist, which is much more than just the name of the process.

I didn't want to just hard code in a fix that would break for the next use case, so instead I whipped up something different that'll work for you. It loves spaces and it's dynamic so it'll work for other cases later on.

Cmd:

set "zTarget=Secure System"
tasklist /nh /fi "imagename eq %zTarget%" 2>&1 | findstr /c:"%zTarget%" >nul 2>&1 && (echo yes, {%zTarget%} is running) || (echo no, {%zTarget%} is not running)

Output:

yes, {Secure System} is running

Answer 2

This is not the most elegant method of solving the problem, but it shows how you can do it. We basically determine how many spaces are in the application name and then call the appropriate FOR.

set EXE=Memory Compression
set count=0
for %%a in (%EXE%) do set /a count+=1
IF "%count%"=="1" FOR /F %%G IN ('tasklist /NH /FI "IMAGENAME eq %EXE%"') DO IF "%%G" == "%EXE%" echo app is running...
IF "%count%"=="2" FOR /F  "tokens=1,2" %%G IN ('tasklist /NH /FI "IMAGENAME eq %EXE%"') DO IF "%%G %%H" == "%EXE%" echo app is running...
IF "%count%"=="3" FOR /F  "tokens=1,2,3" %%G IN ('tasklist /NH /FI "IMAGENAME eq %EXE%"') DO IF "%%G %%H %%I" == "%EXE%" echo app is running...
IF "%count%"=="4" FOR /F  "tokens=1,2,3,4" %%G IN ('tasklist /NH /FI "IMAGENAME eq %EXE%"') DO IF "%%G %%H %%I %%J" == "%EXE%" echo app is running...

Answer 3

Here's my initial comment as an answer:

@Set "EXE=Plex Media Server.exe"
@TaskList|Find /I "%EXE%">Nul&&Echo Plex is running...

---

If you wanted to continue with the For loop method, I'd suggest doing it like this:

@Set "EXE=Plex Media Server.exe"
@For /F Delims^=^" %%A In ('TaskList /Fi "ImageName Eq %EXE%" /Fo:CSV /NH'
)Do @If /I "%%A"=="%EXE%" Echo %%~nA is running...

This could be further refined by including a Find command something along the lines of ('TaskList /Fi "ImageName Eq %EXE%" /Fo:CSV /NH^|Find /I "%EXE%"') , but I have left that out because you're using an If command against the returned output.