VBA：如何通过工作表模块中的“填充”或“复制/粘贴”（或任何多个单元格）找到正在编辑的范围

Question

I have two worksheets with five columns that I want to keep track of any changes made. I present the original state of these columns in worksheet A and mark the change in worksheet B.

Screenshot of worksheet B

Following is the look of worksheet B, let's say that worksheet A has the "ORIG" part but with filters and everthing:

Note: I already wrote another worksheet subroutine, that will filter to "All the same?" = False (meaning that this row is changed) whenever this worksheet is activated.

I already wrote the code that would work for the change of one cell (eg when you edit the cell with F2 and then hit ENTER when you are done) -- a worksheet subroutine that is triggered when the worksheet is changed. The subroutine will check for the changed range, and if the range is a specified area, correponding area is updated in another worksheet.

Worksheet Subroutine

Private Sub Worksheet_Change(ByVal target As Range)
    Dim start_row As Long: start_row = 4
    Dim last_row As Long: last_row = findLastRow()

' when values are changed in "REPORT", check if values are ouputable and update these values
    If IsInArray(Number2Letter(target.Column), inputColumns) And target.row >= start_row And target.row <= last_row Then
        ' Update corresponding cell in worksheetB
    End If
End Sub

Other UDF/UDS

Public Function Number2Letter(ColumnNumber As Long) As String
'convert a given number into it's corresponding Letter Reference
    Dim columnLetter As String
    columnLetter = Split(Cells(1, ColumnNumber).Address, "$")(1)
    Number2Letter = columnLetter
End Function

Public Function IsInArray(valToBeFound As Variant, arr As Variant) As Boolean
'INPUT: Pass the function a value to search for and an array of values of any data type.
'OUTPUT: True if is in array, false otherwise

    Dim element As Variant
    On Error GoTo IsInArrayError: 'array is empty
        For Each element In arr
            If element = valToBeFound Then
                IsInArray = True
                Exit Function
            End If
        Next element
    Exit Function
IsInArrayError:
    On Error GoTo 0
    IsInArray = False
End Function

Public Function findLastRow() As Long
'Finds the last non-blank cell on a sheet
    Dim lRow As Long
        lRow = Cells.Find(what:="*", _
                        After:=Range("A1"), _
                        lookat:=xlPart, _
                        LookIn:=xlFormulas, _
                        SearchOrder:=xlByRows, _
                        SearchDirection:=xlPrevious, _
                        MatchCase:=False).row
    findLastRow = lRow
End Function

For simplicity, I hid the "do something" part, but that part already works. Same thing with UDF/UDS as I only showed them if someone is interested. In addition, the array inputColumns already exists, so don't worry about that part either.

What I am asking for:

1. Is there such a property like targetRange that would work for fill down or paste, like I mentioned?
2. Or is there a different worksheet event that I can use?
3. If neither exists, I am thinking of mark original state in an array and compare it with what is visible on first worksheet every time we get to worksheet B. The problem with this approach is that it consumes both space and speed. Could you think of a better way?

Thank you!

Answer 1

I think that the Intersect function will help you out a lot here. You can define a range that you want to 'audit' and compare it against all the values that are changed by a single operation in your worksheet. If there's any overlap, write out the value of those cells to some target destination.

Private Sub Worksheet_Change(ByVal target As Range)

    Dim AuditRange As Range
    Set AuditRange = Range("B4:F16") 'your "Audit Area"

    Set range_auditedAndChanged = Intersect(target, AuditRange)
    If Not range_auditedAndChanged Is Nothing Then

        For Each c In range_auditedAndChanged
                'put in whereever your audit workbook is for Sheets("Sheet2")
                Sheets("Sheet2").Range(c.Address).Value = c.Value
        Next c

    End If
End Sub

Right now, you only get the values audited - no formats of any kind. You could change the Value assignment to some kind of copy, but that would hijack the user experience for a moment even with screen updating turned off.

At any rate, I think this is cleaner and quite performant and has a lot fewer UDFs to manage. Hope it helps.