如何为用 Excel VBA 编写的电子邮件在嵌入 HTML 的图像之间添加间隙或空格？

Question

I am sending an Outlook e-mail from Excel VBA, which picks up 2 Images to display in the Body of the e-mail. I can successfully get the Images to display next to each other, but I would like a gap or a space between them - how can I add this in?

I don't want them on separate rows.

I have tried using img tags of "hspace", "border" and "margin" but they don't seem to be recognised or read as they have no effect whatsoever on the display layout of the images. Or I'm writing them wrong!

Public Sub EmailData()

Dim OutApp As Object
Dim OutMail As Object
Dim Top10CompaniesPicLocation As String
Dim ReasonsPicLocation As String

Top10CompaniesPicLocation = "\\Images\Top10Companies.jpg"
ReasonsPicLocation = "\\Images\ReasonsTotals.jpg"

Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)

With OutMail
.To = ""
.Subject = "Performance"
 .Attachments.Add Top10CompaniesPicLocation, 1, 0
 .Attachments.Add ReasonsPicLocation, 1, 0

.HTMLBody = "Good Morning,<br><br>Please see below for snapshots of the Performance.<br><br>"
    
.HTMLBody = .HTMLBody _
& "<img src='cid:Top10Companies.jpg'>" _
& "  " _
& "<img src='cid:ReasonsTotals.jpg'><br><br><br>" _
& "Kind Regards<br><br><br>"

'.Send
.Display

End With

Set OutApp = Nothing
Set OutMail = Nothing

End Sub

Answer 1

In Outlook 2007-2019, hspace , border and margin do not work on <img>

The most consistent way to set a gap of say 20 pixels is to build a table and apply the padding to the td cell.

Something like this:

<table role='presentation' cellspacing='0' cellpadding='0' border='0' width='100%'>
  <tr>
    <td style='padding: 10px 10px 10px 0px;'>
        <img src='cid:Top10Companies.jpg'>
    </td>
    <td style='padding: 10px 0px 10px 10px;'>
        <img src='cid:ReasonsTotals.jpg'>
    </td>
  </tr>
</table>

The padding is set to add a little padding on top, bottom, but no padding on the left side of the left image to preserve left alignment with other objects in the email.

If you're into brevity, you might be able to make the table simpler by doing this:

<table cellspacing='4' width='100%'>
  <tr>
    <td>
      <img src='cid:Top10Companies.jpg'>
    </td>
    <td>
      <img src='cid:ReasonsTotals.jpg'>
    </td>
  </tr>
</table>

That puts an 8px gap between the images, but pushes the left image 4px away from the left margin.

Good luck.

Answer 2

Thank you Luis Curado and gwally. Both of your suggestions work for exactly what I want to achieve - the below code includes both solutions.

Public Sub EmailData()

Dim OutApp As Object
Dim OutMail As Object
Dim Top10CompaniesPicLocation As String
Dim ReasonsPicLocation As String

Top10CompaniesPicLocation = "\\Images\Top10Companies.jpg"
ReasonsPicLocation = "\\Images\ReasonsTotals.jpg"

Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)

With OutMail
.To = ""
.Subject = "Performance"
.Attachments.Add Top10CompaniesPicLocation, 1, 0
.Attachments.Add ReasonsPicLocation, 1, 0

.HTMLBody = "Good Morning,<br><br>Please see below for snapshots of the Performance.<br><br>"

.HTMLBody = .HTMLBody _
& "<img src='cid:Top10Companies.jpg'>" _
& "&nbsp&nbsp&nbsp&nbsp  " _
& "<img src='cid:ReasonsTotals.jpg'><br><br><br>"

.HTMLBody = .HTMLBody _
& "<table role='presentation' cellspacing='0' cellpadding='0' border='0' width='100%'>" _
& "  <tr>" _
& "    <td style='padding: 10px 10px 10px 0px;'>" _
& "        <img src='cid:Top10Companies.jpg'>" _
& "    </td>" _
& "    <td style='padding: 10px 0px 10px 10px;'>" _
& "        <img src='cid:ReasonsTotals.jpg'>" _
& "    </td>" _
& "  </tr>" _
& "</table>" _
& "Kind Regards<br><br><br>"

'.Send
.Display

End With

Set OutApp = Nothing
Set OutMail = Nothing

End Sub